Plusieurs références dans la même cellule
Bonjour,
Merci d'avance à qui m'aidera. je cherche la formule qui me permet de compter le nombre de "A" et "C" et "G" dans les plages par exemple D1-G50 ceci seulement si dans les cellule A4 à A50 il y a le mot "Laci"et le mot "RI"
J'espère être assez clair quand je le fais sur une seule ligne avec une seule recherce par exemple "Laci" cela fonctionne mais dès que je désire étendre alors impossible.
Merci beaucoup
Camon
Bonsoir
Si les cellules contiennent A, C et G seuls, c'est à dire, si ces lettres sont isolées et ne font pas partie d'un mot;
=SI(ET(NB.SI(A4:A50;"Laci");NB.SI(A4:A50;"RI"));NB.SI(D1:G50;"A")&"A, "&NB.SI(D1:G50;"C")&"C et "&NB.SI(D1:G50;"G")&" G";"")
Cordialement,
Amadéus
Bonjour,
Et un grand merci pour cette réponse, tout à coup je me sens moins seul.
Mais il y a encore un petit mais...
J'ai besoin du total de "A" ou de "B" ou de "C" ensemble et pas séparément soit
3xA + 5 x C+ 10x G = 18 voilà juste la somme de toutes ces lettres.
J'ai tenté de modifier la formule mais je suis toujours dans le flou.
Merci d'avance de ton aide et de partager tes compétences.
Déjà bonne journée
Camon
Bonjour
Pour avoir la somme:
=NB.SI(D1:G50;"A") donne le nombre de A
=NB.SI((D1:G50;"C") donne le nombre de C
=NB.SI(D1:G50;"G") donne le nombre de G
et
NB.SI(D1:G50;"A")+NB.SI(D1:G50;"C")+NB.SI(D1:G50;"G") donne la somme des trois.
La Formule est donc:
=SI(ET(NB.SI(A4:A50;"Laci");NB.SI(A4:A50;"RI"));NB.SI(D1:G50;"A")+NB.SI(D1:G50;"C")+NB.SI(D1:G50;"G");"")
et si au lieu de ne rien mettre comme résultat, si Laci ou RI ne figurent pas, on veut indiquer que les conditions ne sont pas remplies, on peut écrire:
=SI(ET(NB.SI(A4:A50;"Laci");NB.SI(A4:A50;"RI"));NB.SI(D1:G50;"A")+NB.SI(D1:G50;"C")+NB.SI(D1:G50;"G");"Les conditions ne sont pas remplies!")
Cordialement
Amadéus
Merci Amadeus pour non seulement ta prompte réponse, mais aussi ta gentillesse de mettre à notre disposition tes connaissances.
Ok la formule fonctionne avec un seul défaut (mais imporrtant) il additionne les A +C +G alors qu'il sont en face d'une ligne avec un autre nom que Laci ou RI donc mes résultat sont faux.
Comment éliminer ce problème ?
Merci d'avance si tu as la solution.
Camon
Re Bonjour
C'est sur! Lorsque le problème n'est pas correctement posé, la solution n'est pas forcément celle qu'on attend.
La question d'origine exprime que Laci ET RI doivent figurer sur la plage A4:A50.
Petite explication:
1) Avec la Formule
=SI(ET(NB.SI(A4:A50;"Laci");NB.SI(A4:A50;"RI"));NB.SI(D1:G50;"A")+NB.SI(D1:G50;"C")+NB.SI(D1:G50;"G");"")
Aucun résultat ne peut apparaître si Laci ET RI (les deux!) ne figurent pas dans la plage A4:A50, et à fortiori si, Laci et RI n'étant pas là, il figure un autre texte à la place.
En clair, la formule dit:
Si Laci et RI figurent au moins une fois dans la plage A4:A50, alors donne la somme des A, C et G que contient la Plage D1:G50 Du reste, si vous effacez soit Laci, soit RI de la plage A4:A50, le résultat est une cellule vide.
2) Maintenant, si Laci et RI figurent au moins une fois dans la plage, vous pouvez compléter la plage avec pomme, poire ou Dupont et Durand, le résultat sera toujours la somme des A, C et G de la plage D1:G50.
3) Votre dernier message n'est concevable que si:
-A) Le premier message était faux et qu'en fait, vous souhaitez obtenir le total des A, C et G d'une ligne (et non plus de la plage) si Laci ou RI figurent sur la même ligne.
=SI(OU(A4="Laci";A4="RI");NB.SI(D4:G4;"A")+NB.SI(D4:G4;"C")+NB.SI(D4:G4;"G");"")
Cette solution est imagée sur la Feuil2 du classeur.
-B) Vous souhaitez obtenir le total des A, C, G de la plage D1:D50 uniquement sur les lignes contenant Laci ou RI.
=SI(OU(A4="Laci";A4="RI");NB.SI($D$1:$G$50;"A")+NB.SI($D$1:$G$50;"C")+NB.SI($D$1:$G$50;"G");"")
Cette solution est imagée sur la Feuil3 du classeur joint.
Cordialement
Amadéus
https://www.excel-pratique.com/~files/doc/XMAN7Classeur2.xls
Amadeus,
Pour être plus clair voilà le fichier concerné.
https://www.excel-pratique.com/~files/doc/s2evXTest%20formules.xls
Un très grand merci
jJe vais tenter la solution et ne manquerais pas de donner des nouvelles
Re Re Bonjour camon
Pas d'inquiétude pour le lien. Il faut tout copier et le coller dans la barre du navigateur.
Pour la prochaine fois, il faut nommer les fichiers sans espace.
Bon, ceci dit, je n'arrête pas de le dire, envoyer un bout de fichier est bien la meilleure solution.
Votre formule est un peu complexe, mais fonctionne impec. Le fichier en retour est corrigé.
Pour les curieux:
=SOMMEPROD((($B$4:$B$70="laci")*1)*($G$4:$T$70="A"))+SOMMEPROD((($B$4:$B$70="laci")*1)*($G$4:$T$70="C"))+SOMMEPROD((($B$4:$B$70="laci")*1)*($G$4:$T$70="G"))+SOMMEPROD((($B$4:$B$70="RI")*1)*($G$4:$T$70="A"))+SOMMEPROD((($B$4:$B$70="RI")*1)*($G$4:$T$70="C"))+SOMMEPROD((($B$4:$B$70="RI")*1)*($G$4:$T$70="G"))
Je pensais pouvoir faire plus court, mais...Vous me direz si cela vous convient.
Cordialement,
Amadéus
Bonjour Amadeus,
Oui tout fonctionne génial un grand merci.
J'ai changé les semaines j'ai ajouté des lettres, l'ensemble fonctionne.
Bravo et encore merci.
Bonne journée
Camon
Bonsoir
Il y a moyen de simplifier la formule d'Amadéus
=SOMMEPROD((($B$4:$B$70="laci")+($B$4:$B$70="RI"))*(($G$4:$T$70="A")+($G$4:$T$70="C")+($G$4:$T$70="G")))
@+Jean-Marie
Bonjour Jean-Marie,
merci pour ta proposition, je ne manquerais pas tenter l'expérience.
Bon w-e
Camon