Onglet Direct Ligne

Bonjour,

Je vous soumet ici un cas que je n'ai jamais vu abordé auparavant

Dans le fichier joint en premier onglet j'ai en menu déroulant qui désignera l'onglet désiré

en bas je rentre un chiffre manuellement

1) est-il faisable via une macro que l'onglet désiré s'ouvre et ce positionne exactement ou le chiffre est présent ?

2) De manière pratique est-il possible que le menu déroulant s'alimente des onglet existant commençant par "Log*" dans le classeur?

Merci de vos réponses et de votre persévérance

Cordialement

Bonjour barachoie,

si la valeur en cellule K8 n'est pas trouvée, j'ai présumé qu'il fallait faire un déplacement vers la cellule C1 de la feuille concernée.

Private Sub Worksheet_Change(ByVal Target As Range)
Dim n As Long
If Target.Address = "$K$6" Then
 If Not IsError(Application.Match(Range("K8"), Sheets(Target.Value).Range("C:C"), 0)) Then
  n = Application.Match(Range("K8"), Sheets(Target.Value).Range("C:C"), 0)
  Application.Goto Sheets(Target.Value).Range("C" & n)
 Else
  Application.Goto Sheets(Target.Value).Range("C1")
 End If
End If
End Sub

Bonjour, Salut sabV

Sub OuvrirOnglet()
    Dim nF$, n&, c As Range
    With ActiveSheet
        nF = .Range("K6")
        n = .Range("K8")
    End With
    If nF <> "" Then
        With Worksheets(nF)
            .Activate
            .Range("C1").Select
            If n <> 0 Then Set c = .Columns("C").Find(n, , xlValues)
            If Not c Is Nothing Then
                c.Select
                ActiveWindow.ScrollRow = c.Row
            End If
        End With
    End If
End Sub

Macro attachée à ton image "Finder" !

NB- Probabilités faibles d'avoir le nombre...

Sub RéinitListe()
    Dim ws As Worksheet, lst
    For Each ws In Worksheets
        If ws.Name Like "Logs*" Then
            lst = lst & "," & ws.Name
        End If
    Next ws
    With Worksheets("TraitementDirect").Range("K6").Validation
        .Delete
        .Add xlValidateList, , , Replace(lst, ",", "", 1, 1)
    End With
End Sub

Lancée à l'ouverture du classeur... Autonome pour que tu puisses éventuellement l'affecter à un bouton.

Cordialement.

Les Gars Merci !!!! à lire vos codes ça a l'air facile mais de ce fait vous en avaient sacrément sous la pédale.....

Chapeau et Respect les Artistes

Merci