Nommer un onglet par rapport à une cellule

Bonjour,

J'ai un fichier avec plusieurs onglets, et j aimerai que le nom de mes onglets affiche AUTOMATIQUEMENT le nom inscrit dans ma cellule H3 de chaque feuille!

exemple :

feuille 1 si H3 = toto l'onglet se nomme automatiquement toto

feuille 2 si H3 = FIFI l'onglet se nomme automatiquement FIFI

ETC...

Cdlt

Bonjour,

Supposons que la cellule H3 soit une cellule de saisie, voici un essai avec ce code à placer dans le module ThisWorkbook :

private sub workbook_sheetchange(byval sh as object, byval target as range)
set r = intersect(target, sh.range("H3"))
if not r is nothing then
    if FeuilleExiste(cstr(r.value)) then "Existe dejà": exit sub
    if r.value = "" or r.value like "*[*?'\/[[]*" or r.value like "*]*" or len(r.value) > 30 then
        msgbox "Les noms de feuille sont soumis à certaines restrictions !"
        exit sub
    end if
    sh.name = r.value
end if
end sub

function FeuilleExiste(NomFeuille$) as boolean
on error resume next
FeuilleExiste = sheets(NomFeuille).index
end function

Cdlt,

Bonjour,

Merci mais ça bug sur ça

Quel est le message ? Avez-vous copié le code de la fonction également ?

Private Sub workbook_sheetchange(ByVal sh As Object, ByVal target As Range)
Dim r As Range
Set r = Intersect(target, sh.Range("H3"))
If Not r Is Nothing Then
    If FeuilleExiste(r.Value) Then MsgBox ("Existe dejà"): Exit Sub
    If r.Value = "" Or r.Value Like "*[*?'\/[[]*" Or r.Value Like "*]*" Or Len(r.Value) > 30 Then
        MsgBox "Les noms de feuille sont soumis à certaines restrictions !"
        Exit Sub
    End If
    sh.Name = r.Value
End If
End Sub

Function FeuilleExiste(NomFeuille$) As Boolean
On Error Resume Next
FeuilleExiste = Sheets(NomFeuille).Index
On Error GoTo 0
End Function

Il manquait le msgbox.

Aussi, j'ai ajouté un on error goto 0 dans la fonction.

Je viens d'éditer le code s'il s'agit d'une incompatibilité de type...

Pas besoin je crois, la gestion d'erreurs est propre à la fonction comme vous avez pu le constater.

Cdlt,

ça me m'était ça...

Code rectifié,

ça fonctionne très bien

Merci à vous 2!

Cdlt

Oui, désolé j'ai oublié la msgbox et en plus je vous ai confondus gmourmant et toi (à cause du "g"). Il est temps que j'aille me coucher...

Bonne nuit,