Nombre de jours de janvier 2020 entre le 04/01/2020 et le 05/02/2020

Bonjour à toutes et à tous,

Je souhaite trouver une formule qui me permet d'avoir, par exemple, le nombre de jour correspondant au mois de janvier 2020, entre la plage 04/01/2020 et 05/02/2020, soit une formule qui donnerait : 28 jours en D2, et en appliquant le même principe donnerait 5 jours pour février 2020 en E2, et 0 jours pour mars 2020 en F2, avec un lien dans la formule vers l'entête de colonne (D1, D2...).

J'imagne qu'avec un combiné datedif(), mois(), et/ou sommeprod(), on doit pouvoir y arriver, mais je ne vois pas du tout comment.

Merci d'avance pour vos contributions

Me revoici ...

Essaie :

=SI(ET(MOIS($C4)=MOIS(E$3);MOIS($D4)=MOIS($C4));$D4-$C4+1;0)+SI(ET(MOIS($C4)=MOIS(E$3);MOIS($D4)<>MOIS(E$3));FIN.MOIS($C4;0)-$C4;0)+SI(ET(MOIS($D4)=MOIS(E$3);MOIS($D4)>MOIS($C4));$D4-E$3+1;0)

Un peu tiré par les cheveux ... Mais repris de ton dernier post, qui était plus complet. Tu vérifieras, mais il me semble que tu avais une erreur pour mai.

Bonjour,

@JoyeuxNoel,

Quel outil utilises-tu pour ton animation ?

Cdlt.

Bonjour à tous

Une autre proposition

=SI(ET(E$3<=$D4;FIN.MOIS(E$3;0)>=$C4);MIN(FIN.MOIS(E$3;0);$D4)-MAX(E$3-1;$C4);0)

Hello Jean-Éric,

T'as vu, ça monte vite en gamme, hein? ;)

Sur les conseils de GGautier, j'utilise licecap

Petit utilitaire super simple et sympa, qui fait des gifs de la partie d'écran que tu lui demandes d'enregistrer. 100% free to use.

@Chris, oui, bon, OK, si tu le prends comme ça .... Pfff si on ne peut même plus se compliquer la vie ...

Merci @JoyeuxNoel !!

Et parfait pour la fonction sous-total que je n'avais jamais utilisée jusque là, et qui est bien pratique.

La formule marche pour le premier mois et le dernier mois de la période considérée, mais si on prends le cas d'un plage à cheval sur plusieurs mois, on n'a pas les données pour les mois complets.

Exemple : j'ai changé les dates en C4 et C5 (en vert), le calcul ne se fait pas dans les cellules oranges.

Concernant les fin de mois (en jaune) manque juste un jour chaque fois si je veux inclure la première date (il s'agit de contrats de travail, et le but est d'avoir le nombre de jours sous contrat, donc je prends en compte le 1er jour et le dernier jour), j'ai testé avec FIN.MOIS($B4;0)-$B4+1;0) et ça fonctionne.

Arf, pourquoi n'ai-je pas senti le coup venir ?

Tu n'avais que des données à cheval sur 2 mois, la méthode (bancale en plus) que je t'ai donnée ne fonctionne pas si l'écart de mois est plus important.

Mais la superbe fonction de Chris tournera sans souci dans ton fichier.

Merci à tous

Après avoir bataillé pendant 10 minutes pour comprendre pourquoi formule "ne marchait pas", -> il fallait juste que je décale les lettre d'un cran (je me suis senti bête)

=SI(ET(D$3<=$C4;FIN.MOIS(D$3;0)>=$B4);MIN(FIN.MOIS(D$3;0);$C4)-MAX(D$3-1;$B4);0) NICKEL ça fonctionne,

Il restait juste éventuellement le coup des fin de mois où il fallait que je rajoute un "plus un", j'ai essayé mais du coup ça me faisait des mois en 32 jours pour les mois pleins , mais après avoir bataillé, j'ai la formule finale qui fonctionne bien et prends tous les paramètres en compte :

=SI((SI(ET(D$3<=$C4;FIN.MOIS(D$3;0)>=$B4);MIN(FIN.MOIS(D$3;0)+1;$C4)-MAX(D$3-1;$B4);0))>JOUR(FIN.MOIS(D3;0));JOUR(FIN.MOIS(D3;0));SI(ET(D$3<=$C4;FIN.MOIS(D$3;0)>=$B4);MIN(FIN.MOIS(D$3;0)+1;$C4)-MAX(D$3-1;$B4);0))

Merci encore 

RE

Modifie ainsi

=SI(ET(D$3<=$C4;FIN.MOIS(D$3;0)>=$B4);MIN(FIN.MOIS(D$3;0);$C4)-MAX(D$3-1;$B4-1);0)

Merci c'est parfait !