Mise en forme note/commentaire

Bonjour tout le monde!

le contexte de mon problème:

j'ai automatise des notes pour qu'elle se remplisse seul en adressant des cellules, sauf que le contenant de ces cellule varie en nombre de lettre se qui me rend la tache compliqué pour mettre en gras certain adressage ...

Je vous met en gras souligner les éléments que j'aimerais mettre en gras, je vous remercie d'avance si vous avez des idées !

Sub DPPh()
'commentaire 1

'supprime les commentaires avant de lancer la création des commenataires
Range("g18:g18").ClearNotes
'ajouter un commentaire
Range("g18").AddComment

'permet d'afficher ou de masquer le commentaire
Range("g18").comment.Visible = False

'Taille de la fenêtre du commentaire
Range("g18").comment.Shape.Width = 300
Range("g18").comment.Shape.Height = 200



'texte du commentaire
Range("g18").comment.Text Text:="Thonont, Maeva:" & Chr(10) & "Testé le " & Sheets("Schém Plaq").Cells(1, 19) & " sur DPPH" _
& Chr(10) & Sheets("Schém Plaq").Cells(10, 5)

Bonjour Maeva_9

Voici le code optimisé pour faire ce que vous souhaitez

Sub DPPh()
  Dim LeTexte As String
  ' Le texte du commentaire
  LeTexte = "Thonont, Maeva:" & Chr(10) & "Testé le " & Sheets("Schém Plaq").Cells(1, 19) & " sur DPPH" _
     & Chr(10) & Sheets("Schém Plaq").Cells(10, 5)
  ' Avec la cellule
  With Range("G18")
    .ClearNotes
    With .AddComment(LeTexte).Shape
      .Width = 300
      .Height = 200
      With .TextFrame.Characters(1, Len("Thonont, Maeva")).Font 'caractère départ : 1, longueur du texte
        .Bold = True
        '.Underline = True
        '.italic = true 'en italique
        '.color = RGB(0, 0, 255) 'en bleu
      End With
      With .TextFrame.Characters(InStr(1, LeTexte, "le") + 3, 10).Font 'caractère départ : après le de testé, longueur d'une date
        .Bold = True
        '.Underline = True
        '.italic = true 'en italique
        '.color = RGB(0, 0, 255) 'en bleu
      End With

    End With
  End With
End Sub

A+

super merci beaucoup !

Re,

Au fait

Lorsque la réponse vous apporte la solution merci de cliquer sur son petit V à droite SVP pour la marquer

Au plaisir