MFC Planning

Bonjour à tous,

J'ai un souci au niveau des mises en forme conditionnelle que je ne maitrise absolument pas bien que je me débrouille en Excel.

J'ai 4 colonnes intitulées D1, D2, F1 et F2 (ce sont des dates) avec les différentes combinaisons ci-dessous possibles:

Cas 1: Quand D1 est renseignée, F1 l'est également et F1 est toujours > D1 (D2 et F2 peuvent être vides)

=> On a donc F1>D1 et D2 et F2=""

Cas 2: Quand D1 est renseignée, F1 l'est toujours et D2 peut l'être aussi (F2 peut dans ce cas être vide)

=> On a donc F1>D2>D1 et F2=""

Cas 3: On peut avoir le cas où les 4 dates sont renseignées

=> On a donc F2>F1>D2>D1

Ce que je voudrais:

Dans le cas 1, lorsque la date du planning Gantt est égale à D1 et F1 qu'il me colorie toutes les cellules entre les 2 dates en VERT

Dans le cas 2, colorie en VERT les cellules allant de D1 à D2, colorie en ORANGE LA cellule égale à D2 et à nouveau en VERT les cellules allant de D2 à F1

Dans le cas 3, colorie en VERT les cellules allant de D1 à D2, colorie en ORANGE la cellule égale à D2 et à nouveau en VERT les cellules allant de D2 à F1 puis en ROUGE les cellules allant de F1 à F2

Contrainte: je ne souhaite pas que les cellules qui tombent un w-e ou un jour férié (voir exemple dans le fichier) soit coloriée dans le planning

Je vous joins un fichier qui sera beaucoup plus clair que mes explications

Merci par avance de votre aide précieuse car je susi totalement perdu.

N'hésitez pas si vous avez des questions.

Bonjour

MFC en E4

Condition1

"La Formule est"

=ET(NB.SI(Fériés;$B4)=0;JOURSEM($B4;2)<6;$B4=E$2)

Couleur Orange

Condition2

"La Formule est"

=SOMMEPROD((LIGNE(INDIRECT($A4&":"&$C4))=E$2)*(NB.SI(Fériés;LIGNE(INDIRECT($A4&":"&$C4)))=0)*(JOURSEM(LIGNE(INDIRECT($A4&":"&$C4));2)<6))

Couleur Vert

Condition3

"La Formule est"

=SOMMEPROD((LIGNE(INDIRECT($C4&":"&$D4))=E$2)*(NB.SI(Fériés;LIGNE(INDIRECT($C4&":"&$D4)))=0)*(JOURSEM(LIGNE(INDIRECT($C4&":"&$D4));2)<6))

Couleur Rouge

Cordialement

Merci Amadeux, c'est juste nickel, ça marche parfaitement.

Par contre, j'ai identifié 2 besoins supplémentaires qui sont en lien avec mes premières demandes...peux-tu également m'aider STP:

Je peux également avoir un cas où F2 est inférieur à F1 et ce, peu importe si D2 est renseigné ou non. Dans ce cas, je souhaiterais que LA cellule égale à F2 soit dans un format différent (voir exemple dans le fichier joint)

Enfin, j'ai ajouté une colonne "Statut" et je souhaiterais que lorsque le statut est égal à "Finalisée" ou "Annulée", toute la barre du planning se colorie en bleu peu importe la configuration (uniquement D1 et F1 renseignées ou D1, F1 et F2 renseignées ou encore D1, D2, F1 et F2 renseignées).

Merci beaucoup pour ton aide précieuse, vraiment.

Bonjour

Tu viens d'ajouter une 4ème couleur.

Désolé, ma version Excel 2003 n'en accepte que 3.

J'espère qu'un autre prendra le relai

Cordialement

Merci de ton retour.

Est-il éventuellement possible que tu me communiques la formule ?

Bonjour

Attention à respecter l'ordre des conditions

MFC en F4

Condition1

"La Formule est"

=ET(NB.SI(Fériés;$B4)=0;JOURSEM($B4;2)<6;OU($E4="Finalisée";$E4="Annulée"))

Couleur Bleu

Condition2

"La Formule est"

=ET($D4<$C4;$D4=F$2)

Couleur vide ,Motif Hachuré

Condition3

"La Formule est"

=ET(NB.SI(Fériés;$B4)=0;JOURSEM($B4;2)<6;$B4=F$2)

Couleur Orange

Condition4

"La Formule est"

=SOMMEPROD((LIGNE(INDIRECT($A4&":"&$C4))=F$2)*(NB.SI(Fériés;LIGNE(INDIRECT($A4&":"&$C4)))=0)*(JOURSEM(LIGNE(INDIRECT($A4&":"&$C4));2)<6))

Couleur Vert

Condition5

"La Formule est"

=SOMMEPROD((LIGNE(INDIRECT($C4&":"&$D4))=F$2)*(NB.SI(Fériés;LIGNE(INDIRECT($C4&":"&$D4)))=0)*(JOURSEM(LIGNE(INDIRECT($C4&":"&$D4));2)<6))

Couleur Rouge

A contrôler sur ton fichier, bien sur.

Cordialement

Merci Amadéus c'est juste parfait.

Merci bcp.