Mettre des donnees dans un tableau en fonction d'un combobox

Bonjour a tous,

Je reviens vous sollicitez car je me retrouve bloque sur une nouvelle application. J'espere donc trouver de l'aide ici.

Donc j'ai un tableu avec differentes matieres, le but et de selectionner une matiere dans le combobox et de saisir la note dans le textbox. Ensuite la note doit etre directement mis dans le tableau au bonne emplacement. De plus si je souhaite ajouter un seconde note, j'aimerais que la note soit mise a la suite.

En esperant trouver de l'aide je vous remercie d'avance pour votre temps.

Cordialemment.

Re: je met la PJ

Bonjour,

Proposition :

Private Sub Cmd_Valider1_Click()
    Dim n%, k%
    If TextBox1.Value = "" Then
        MsgBox "Mettre une note.", vbExclamation, "Notation"
        Exit Sub
    End If
    n = ComboBox1.ListIndex + 1
    If n > 0 Then
        With [Notes]
            k = .Cells(n, 1).End(xlToRight).Column + 1
            If k > Worksheets("Feuil1").Columns.Count Then k = 2
            .Cells(n, k).Value = TextBox1.Value
            .Cells(n, k).Select
        End With
        TextBox1.Value = ""
        ComboBox1.ListIndex = -1
    Else
        MsgBox "Sélectionner une matière.", vbExclamation, "Notation"
    End If
End Sub

Tu noteras que j'ai nommé la plage des matières : Notes, pour plus de confort d'utilisation.

Par la même occasion cela permet de te passe de procédure Inotialize, car il suffit d'affecter la plage (par son nom) à la propriété RowSource du ComboBox. [C'était déjà possible en indiquant la référence.]

Si tu devais ajouter des matières, il conviendrait de rendre la référence au nom dynamique, de façon à n'avoir rien à changer.

Après inscription, les données sont effacées dans le Userform pour permettre une nouvelle notation. Si cette disposition convient, il conviendrait d'ajouter un bouton pour fermer le Userform, sinon à remplacer par la fermeture du Userform dans la procédure.

Cordialement