Macro sélectionner dernière colonne d'un tableau

Bonjour,

J'aimerais aujourd'hui réaliser une macro qui me sélectionne la case L17 en sachant que cette case peut être modifié donc le tableau pourrait être ligne 300 je voudrais toujours réussir à sélectionner la dernière colonne du tableau "comment ?" avec une macro
.
Globalement j'ai essayé cette fonction : "nom page".Cells(17, Columns.Count).End(xlToLeft).Column
Mais le 17 il est inconnu car ce ne sera pas toujours la ligne 17

Quelqu'un aurait une idée de code pour réalisé ça ?

Merci par avance !

Re,

Sub RechercherLaDerniereColonne()

    MsgBox DerniereColonne(Sheets("Feuil1").ListObjects("Tableau44"))

End Sub

Function DerniereColonne(ByVal Tableau As ListObject) As Long

    With Tableau
        DerniereColonne = .DataBodyRange.Column + .DataBodyRange.Columns.Count - 1
    End With

End Function

Bonjour,
Sans conviction car la question est mal formulée.
Cdlt.

Sub Test()
Dim lo As ListObject
    Set lo = ActiveSheet.ListObjects(1)
    lo.ListColumns("Comment ?").Range.Cells(1).Select
End Sub

Bonjour,

Ou encore:

Sub Der_Cell()
    Dim Tabl As ListObject
    Dim Nb_Lig As Long, Nb_Col As Integer
    Set Tabl = Range("Tableau44").ListObject
    With Tabl
        Nb_Lig = .ListRows.Count
        Nb_Col = .ListColumns.Count
        With .DataBodyRange
            .Cells(Nb_Lig, Nb_Col).Select
        End With
    End With
End Sub

Cdlt

Je n'ai en effet pas assez bien expliquer et j'en suis désolé ...

L'objectif de cette macro c'est que je veux pouvoir, avec différentes macros ajouter des tableaux, ajouter/supprimer des lignes au dernier tableau de la feuille et ajouter/supprimer des colonnes au dernier tableau de la feuille également
J'arrive pour l'instant à
- Ajouter une ligne :
Sub Ajoutligne()

Cells(ActiveSheet.Rows.Count, 2).End(xlUp).Select
Selection.ListObject.ListRows.Add

End Sub

-Supprimer une ligne :

Sub DeleteRow()
Dim Plage As Range
Cells(ActiveSheet.Rows.Count, 2).End(xlUp).Select
Set Plage = Intersect(Selection, Union(Range("A31:R300"), Range("A31:R300")))
If Plage Is Nothing Then
MsgBox "Impossible de supprimer"
Else
Cells(ActiveSheet.Rows.Count, 2).End(xlUp).Offset(0, 0).Select
Selection.EntireRow.Delete

End If
End Sub

-Ajouter une colonne :
Sub Ajoutcolonne()

Cells(ActiveSheet.Rows.Count, 2).End(xlUp).Offset(0, 0).Select
Selection.ListObject.ListColumns.Add

End Sub

- Supprimer une Colonne : c'est cette macro que je cherche à faire

Donc la dernière colonne pourrait s'appeler "Lapin" que je voudrais sélectionner cette colonne (qui pourrait être 3 colonne après "comment ?")
Le numéro du tableau ne sera pas fixe donc je ne peux pas utiliser "tableau 44", pour sélectionner le tableau j'utilise la fonction :
Cells(ActiveSheet.Rows.Count, 2).End(xlUp).Select
Pour pouvoir Sélectionner le dernier tableau de la feuille

Ce que je demande donc c'est d'avoir un code qui permet de sélectionner la dernière colonne de ce tableau sans l'appeler par : "Tableau 44" ou alors sélectionner colonne "Comment ?"

Est-ce possible ?

Bien à vous

Bonjour,
Une petite contribution !?
Cdlt.

Option Explicit

Dim lo As ListObject
Dim n As Long

Sub AddColumnInTable()
    With ActiveSheet
        n = .Cells(.Rows.Count, 2).End(xlUp).Row
        Set lo = .Cells(n, 2).ListObject
        lo.ListColumns.Add
    End With
    Set lo = Nothing
End Sub

Sub DeleteLastColumnInTable()
    With ActiveSheet
        n = .Cells(.Rows.Count, 2).End(xlUp).Row
        Set lo = .Cells(n, 2).ListObject
        n = lo.ListColumns.Count
        lo.ListColumns(n).Delete
    End With
    Set lo = Nothing
End Sub

Woa !

Merci énormément Jean-Eric c'est exactement ce que je voulais !
Tu as été d'une efficacité sans nom !! ...