Macro Extract avec conditions
F
Bonjour tous,
Je dispose actuellement d'un tableau avec des numéros de séries, des clients et des dates de livraisons. Ce tableau compose ma base de données sources.
Dans un second onglet j'ai 3 case à remplir manuellement:
- Client
- Début de période
- Fin de période
Voici le tableau test susmentionné :
Je ne sais pas si cela es possible mais ca m'aiderait énormément.
Merci d'avance,
FloBru
Invité
Bonjour FloBru,
Tout est possible en dev.
En utilisant le filtrage des lignes de la feuille Base
Sub ExtractionSérie()
Dim DLig As Long
With Sheets("Base")
' Dernière ligne du tableau
DLig = .Range("A" & Rows.Count).End(xlUp).Row
' vérifier si le filtre est actif, sinon l'activer
If .AutoFilterMode = False Then
.Range("A1").AutoFilter
Else
.ShowAllData
End If
' Crééer les filtres
' Filtre du nom client
.Range("$A$1:$C$" & DLig).AutoFilter Field:=2, Criteria1:=Sheets("Working").Range("B5").Value
' Filtre des dates
.Range("$A$1:$C$" & DLig).AutoFilter Field:=3, Criteria1:=">=" _
& Format(Sheets("Working").Range("C8"), "mm/dd/yyyy"), Operator:=xlAnd, _
Criteria2:="<=" & Format(Sheets("Working").Range("E8"), "mm/dd/yyyy")
' Copie les lignes filtrée avec l'entête de la ligne 1
.Range("A1:A" & DLig).Copy Destination:=Sheets("Working").Range("A12")
End With
End Sub
A+
F
Bonjour BrunoM45,
En effet tout est possible et en plus ta réponse est juste parfaite !!
Merci énormément!
FloBru