Listbox

Bonjour,

Je me permet de vous déranger car malgré des recherches un peut partout je ne trouve pas de solution...

Je souhaiterais remplir une listbox avec des colonne de mon tableau que j'ai nommé, voici comment je m'y prend actuallement :

    Dim i As Integer

    Dim List_Eleve(1 To 14, 1 To 2) As String

    For i = 1 To 14

        List_Eleve(i, 1) = Range("Commentaire_Fraise2Tailles").Offset(i)
        List_Eleve(i, 2) = Range("B1").Offset(i)

    Next i
    ListBox_Fraise2Taille.List() = List_Eleve

Hors j'ai une erreur m'indiquant un problème de type qui ne serais pas compatible... Je ne comprend pas... Pourtant quand je veut remplir seulement une colonne j'y arrive avec le nom de ma colonne : Range("Commentaire_Fraise2Tailles").Value

Si quelqu'un à une solution je suis preneur ^^

Merci d'avance.

Bonjour

Sans fichier pas facile de savoir comment sont organisées tes données

1er cas la colonne B n'est pas à droite de la colonne "Commentaire_Fraise2Tailles"

Private Sub UserForm_Initialize()
Dim i As Integer
Dim List_Eleve(1 To 14, 1 To 2) As String

  With Me.ListBox_Fraise2Taille
    .ColumnCount = 2
  End With

  For i = 1 To 14
    List_Eleve(i, 1) = Range("Commentaire_Fraise2Tailles").Cells(i, 1)
    List_Eleve(i, 2) = Range("B" & i)
  Next i
  ListBox_Fraise2Taille.List() = List_Eleve
End Sub

2ème cas la colonne "Commentaire_Fraise2Tailles" est la colonne A

Private Sub UserForm_Initialize()
  With Me.ListBox_Fraise2Taille
    .ColumnCount = 2
  End With
  ListBox_Fraise2Taille.List = Range("Commentaire_Fraise2Tailles").Resize(, 2).Value
End Sub

Si ce n'est pas ça ton fichier va être indispensable

Bonjour et merci pour ton aide.

Voici un fichier qui vous aideras surement.

Encore merci, je reste disponible pour tout renseignements.

Bonjour

2 solution qui fonctionnent

Private Sub B_Remplir_Click()
Dim i As Integer
Dim List_Eleve(1 To 14, 1 To 2) As String

  For i = 1 To Range("Liste_Prenom").Rows.Count   '14
    List_Eleve(i, 1) = Range("Liste_Prenom").Cells(i, 1)
    List_Eleve(i, 2) = Range("List_Id").Cells(i, 1)
  Next i

  With Me.ListBox
    .ColumnCount = 2
    .List() = List_Eleve
  End With
End Sub

ou

Private Sub B_Remplir_Click()

  With Me.ListBox
    .ColumnCount = 2
    .List() = Range("Liste_Prenom").Resize(, 2).Value
  End With
End Sub

Attention : Pour la 1ère solution si ton tableau fait plus de 14 lignes --> Plantage

Enfin... Le code que vous m'avez donnez fonctionne donc mon fichier ne vas pas beaucoup servir ^^

Merci beaucoup