Inputbox et contenu de cellule

Bonjour

suis un peu bloqué sur un truc tout bete , mais apres avoir tenté plusieurs ecritures possibles ca ne marche pas

j'en appelle à vos lumières ;

le procedé est le suivant , j'ouvre une inputbox, je saisi la chaine de caractères et je compare le contenu aux cellule d'une plage

si une cellule contient la meme chaine que celle inserée dans l'inputbox alors le message est msgbox "trouvé"

j'ai ecrit la macro suivante :

p = InputBox("saisie:")
'  je saisi ensuite  dans l'inputbox:  GARE DE BERCY 
For Each cell In Sheets("lignes").Range("d2:d35000")
     If cell.Value Like "*" & p & "*" And cell.Offset(, 5).Value = Sheets("requête").Range("c8").Value Then
        MsgBox cell.Row
       Exit For
     End If
   Next
End Sub

le soucis est que la formulation

cell.Value Like "*" & p & "*"  

ne convient certainement pas

j'ai tenté avec .value apres cell mais je ne parviens pas à avoir le message attendu ..

Vous remerciant par avance pour toute indication

Cordialement

Bonjour Rocket, bonjour le forum,

Je te propose une méthode bien plus rapide rapide avec l'utilisation d'une variable tableau TV plutôt qu'une plage et la fonction InStr au lieu de Like....

Sub Macro1()
Dim BE As Variant 'déclare la variable BE (Boîte d'Entrée)
Dim TV As Variant 'déclare la variable TV (Tableau des Valeurs)
Dim I As Long 'déclare la variable I (Incrément)

TV = Sheets("lignes").Range("D2:I35000") 'définit le Tableau des Valeurs TV
BE = Application.InputBox("saisie:", Type:=2) 'définit la boîte d'entrée BE
If BE = False Or BE = "" Then Exit Sub 'si bouton [Annuler] ou non renseignée
For I = 1 To UBound(TV, 1) 'boucle sur toutes les lignes I du tableau des valeurs TV
    'si la valeur de P est contenue dans la donnée ligne I colonne 1 de TV et si la donnée ligne I colonne 6 de TV est égale à
    'la valeur de la cellule C8 de l'onglet requête
    If InStr(1, TV(I, 1), BE, vbTextCompare) <> 0 And TV(I, 6) = Sheets("requête").Range("C8").Value Then
        MsgBox I + 1 'renvoie la valeur de I (plus 1 pour correspondre au numéro de ligne réel) dans un message
        Exit For 'sort de la boucle
    End If 'fin de la condition
Next 'prochaine ligne de la boucle
End Sub

Un grand merci ThauTheme je vais tester ca ! une bonne journée à vous