Impression de plusieur onglet

Bonsoir le forum!

j'ai fait un code "avec de l'aide bien sur" pour choisir quels onglets imprimer

pour chaque onglet j'aimerai pourvoir choisir aussi une quantité de copie avec une valeur par défaut fixé à 1. la présentation n'a aucune importance.

je joints un fichier exemple.

je vous remercie d'avance pour l'aide que vous m'apporter

Bonsoir,

J'ai des petits soucis avec les xlsm, j'attends le petit papa noêl pour ne plus en avoir (^_^).

Peux-tu me mettre a disposition un fichier xls, faut-il prévoir un userform pour définir la zone d'impression ?

A te relire

Cdt

Air_2

bonsoir Air-2

le même fichier en xls

il n'y a pas besoin de définir une zone d'impression.

Sur le nouveau fichier détail de ma demande

merci pour ton aide

salut le forum

Peut-être un début de solution pour le nombre de feuille

Il faut d'abord sélectionner un élément avec le clique droit.

• Clique gauche sur le chiffre -1 au nombre de feuille
• Clique droit sur le chiffre +1 au nombre de feuille
• Lorsque zéro on n'imprimerait pas la feuille

Sub ChargeListBox()
Dim s As Object
With Sheets("Feuil1").ListBox1
    .MultiSelect = fmMultiSelectSingle
    .ColumnCount = 2
    .ColumnWidths = "40;20"
    .Enabled = True
    .Clear
  For Each s In Sheets
    .AddItem 'ajout d'une ligne
    .List(.ListCount - 1, 0) = s.Name
    .List(.ListCount - 1, 1) = 1
  Next
End With
End Sub

Private Sub ListBox1_MouseUp(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
  With Sheets("Feuil1").ListBox1
    If Button = 1 Then .List(.ListIndex, 1) = .List(.ListIndex, 1) + 1
    If Button = 2 Then .List(.ListIndex, 1) = .List(.ListIndex, 1) - 1
  End With
End Sub

On teste ensuite l'impression

Sub Imprimer()
Dim i As Integer

With Sheets("Feuil1").ListBox1
  For i = 0 To .ListCount - 1
    If .List(i, 1) > 0 Then Sheets(.List(i, 0)).PrintOut Copies:=.List(i, 1)
  Next i
End With

End Sub

Mytå

Salut le forum

Regarde si cela te convient

Pour le bouton Charger Onglets

Sub ChargeListBox()
Dim Sh As Object
With Sheets("Feuil1").ListBox1
    .MultiSelect = fmMultiSelectExtended
    .ColumnCount = 2
    .ColumnWidths = "60;20"
    .Enabled = True
    .Clear
  For Each Sh In Sheets
   If Sh.Name <> ActiveSheet.Name Then
    .AddItem 'ajout d'une ligne
      .List(.ListCount - 1, 0) = Sh.Name
      .List(.ListCount - 1, 1) = 1
   End If
  Next Sh
End With
End Sub

Un bouton permettant de choisir le nombre de feuille.

Sub NbreFeuille()
Dim Nbre As Byte, I As Integer

Nbre = Application.InputBox("Indiquer le nombre d'impression", Type:=1)

With Sheets("Feuil1").ListBox1
  For I = 0 To .ListCount - 1
    If .Selected(I) Then .List(I, 1) = Nbre
  Next I
End With

End Sub

Pour l'impression

Sub Imprimer()
Dim i As Integer

With Sheets("Feuil1").ListBox1
  For i = 0 To .ListCount - 1
    If .List(i, 1) > 0 Then Sheets(.List(i, 0)).PrintOut Copies:=.List(i, 1)
  Next i
End With

End Sub

Mytå

bonjour

merci à tous tout fonctionne bien juste un petit problème de présentation je vais essayer de régler cela encore merci