Image en commentaire selon valeur cellule

Bonjour à tous,

Complètement nouveau sur ce forum et en macro, je sollicite votre précieuse aide.

Tout est dans le titre, je souhaite, au survol d'une cellule, que s'affiche en commentaire une image correspondant à la valeur de ladite cellule.

Exemple : En cellule A1 est indiquée la référence d'un outil (qui change selon la référence choisi)

Lorsque que l'on passe la souris sur la cellule, s'affiche en commentaire la photo de cet outil.

J'ai déjà le code pour afficher une image sur la feuille selon la valeur d'une cellule mas je n'arrive pas à l'adapter à ce que je souhaite faire :

Dim Val1

Val1 = Sheets("CU7").[CZ17].Value

Dim val2 As String

val2 = ThisWorkbook.Path & "\Photos\"

Dim val3 As String

val3 = val2 & Val1 & ".jpg"

Range("BM17").Select

On Error GoTo erreur1

ActiveSheet.Pictures.Insert(val3).Select

D'avance merci de votre aide.

Si besoin est, je peux mettre un document en pj, mais qui sera allégé car dépasse les 200 ko.

Un petit up en précisant que c'est sur excel 2003, et en ajoutant le fichier pour bien comprendre

Bonjour ElectrO, bienvenue sur le forum,

Essaie en remplaçant la procédure Worksheet_Change de la feuille "CU7" par celle-ci :

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Application.Intersect(Target, [A10]) Is Nothing Then
        DisqueCalibre
    End If
    If Not Application.Intersect(Target, [AC4:AC8]) Is Nothing Then
        chemin = ThisWorkbook.Path & "\Photos\"
        With Target
            nf = Target.Value & ".jpg"
            exist = Dir(chemin & nf) 'regarde si le fichier image existe
            .ClearComments 'supprime le commentaire existant
            If exist = "" Then MsgBox "L'image " & nf & " n'existe pas.": Exit Sub
            .AddComment
            With .Comment.Shape
                .Fill.UserPicture chemin & nf
                .ScaleHeight 1.5, msoFalse, msoScaleFromTopLeft
                .ScaleWidth 1.5, msoFalse, msoScaleFromTopLeft
                .LockAspectRatio = msoTrue
            End With
        End With
    End If
End Sub

Bonjour,

Test effectué mais ça n'a pas l'air de fonctionner, rien ne s'affiche dans le commentaire :s

On dirai que ce n'est pas pris en compte.

Il faut que tu remodifies les cellules en AC4, AC5... pour déclencher l'évènement Change.

Exact !

Mais est-il possible d'avoir le changement d'image sans avoir à revalider la cellule ?

A mon avis, la difficulté va être de prendre en compte ce qu'affiche la cellule, et pas son contenu (la rechercheV)

En fait, ce fichier sera complètement verrouillé et uniquement la case A10 sera modifiable.

L'idéale serait donc que les images en commentaires changent en même temps que ce qu'affiche les cellules.

(il se peux que je m'exprime mal ^^)

J'avais zappé qu'il y avait une fonction recherchev dans la colonne AC !

Vu que la mise à jour des images se fait après avoir modifié la cellule A10, essaie comme ceci :

Private Sub Worksheet_Change(ByVal Target As Range)
  If Not Application.Intersect(Target, [A10]) Is Nothing Then
    DisqueCalibre
    chemin = ThisWorkbook.Path & "\Photos\"
    For Each cel In [AC4:AC8]
      With cel
        If Not IsError(.Value) Then
          nf = .Value & ".jpg"
          exist = Dir(chemin & nf) 'regarde si le fichier image existe
          .ClearComments 'supprime le commentaire existant
          If exist = "" Then
            MsgBox "L'image " & nf & " n'existe pas."
          Else
            .AddComment
            With .Comment.Shape
              .Fill.UserPicture chemin & nf
              .ScaleHeight 1.5, msoFalse, msoScaleFromTopLeft
              .ScaleWidth 1.5, msoFalse, msoScaleFromTopLeft
              .LockAspectRatio = msoTrue
            End With
          End If
        End If
      End With
    Next cel
  End If
End Sub

Ben chapeau bas !

Tout simplement excellent, merci beaucoup, c'est exactement ce que je voulais

J'avais choper du code sur le net, mais j'aurai pas su l'adapter.....encore merci !

Tiens toi prêt pour ma prochaine enigme lol