Guillemets dans mon fichier txt

Bonjour,

A noter que je suis novice... donc je développe comme je peux!!

Mon souci en l'occurence, ma macro me génère un fichier txt qui me va bien sauf que sur chaque ligne j'ai un guillement au début et un autre à la fin ... et je n'en veux pas.

Votre aide me sera précieuse et me fera gagner pas mal de temps.

Au passage dans la combo box, si vous savez comment donner un pré-remplissage du format date avec les / et le nombre de chiffres attendus pour le jour, le mois, l'année , je suis preneur.

Merci d'avance ci-joint le fichier

Bonjour AntoineS

Ce genre de fichier avec données personnelles ne peut être posté sur ce forum ni ailleurs d'ailleurs

je vous invite à relire la charte du forum [A LIRE AVANT DE POSTER]
qui vous aideront dans vos demandes et réponses sur ce forum et notamment

• ne postez JAMAIS de fichiers avec des informations personnelles ou confidentielles (cet utilitaire peut vous aider à les retirer).

Sinon, il faut utiliser "Print" et non "Write" comme instruction, voici le code modifié qui ne contient pas de "Select" inutiles

Sub ExportPegase()
  ' ExportPegase Macro
  ' Lancement boite de dialogue pour récupérer la société à traiter
  UserForm3.Show
  ' Lancement boite de dialogue pour récupérer la date de virement
  Do
    ladate = InputBox("Entrez la date de Virement au format jj/mm/aaaa:", "Virement", "00/00/0000")
  Loop While Not ladate Like "##/##/####"
  ' Nettoyage onglet export
  Sheets("Export vers Pegase").Range("A:O").Clear
  ' Définir la feuille à traiter
  With Sheets(UserForm3.ListBox1.Value)
    ' Sélection des données de la société à traiter
    DerLigne = .Cells(2, 2).End(xlDown).Row
    .Range("B3" & ":O" & DerLigne).Copy
  End With
  ' Copie sur l'onglet d'export vers Pegase
  With Sheets("Export vers Pegase")
    .Range("B1").PasteSpecial Paste:=xlPasteValues
    ' Mise en forme fichier
    .Range("C:N").Delete
    DerLigne2 = .Cells(1, 2).End(xlDown).Row
    For j = 1 To DerLigne2
      .Range("A" & j) = "'00001"
      .Range("D" & j) = ladate
    Next
    Set expRng = .Range("A1" & ":D" & DerLigne2)
    numRows = expRng.Rows.Count
    numCols = expRng.Columns.Count + 1
    Fichier = "O:\PAIE ET SALAIRES\" & UserForm3.ListBox1 & " " & "Acomptes " & Month(ladate) & Year(ladate) & ".txt"
    Open Fichier For Output As #1
    .Range("H1") = numRows
    .Range("H2") = numCols
    For r = 1 To numRows
      data = expRng.Cells(r, 1).Value
      For c = 2 To numCols
        If c <> numCols Then
          data = data & ";" & expRng.Cells(r, c).Value
        Else
          Print #1, data
        End If
      Next c
    Next r
    Close #1
    ' Affichage de fin de traitement
    total = WorksheetFunction.Sum(.Range("C:C"))
  End With
  MsgBox UserForm3.ListBox1 & vbLf & ladate & vbLf & "Virement total de " & total & "€" & vbLf & Fichier
End Sub

A+

C'est cool merci et j'ai bien noté les recommandations de contenu de fichier.