Graphique à bulles

Bonjour à tous,

Je me permets de vous contacter car j'ai crée un graphique à bulles mais je rencontre quelques difficultés.

J'aimerai créer un graphique à bulles avec :

en abscisse: le nombre de contacts

en ordonnée: la catégorie de client

et afficher le nom du client sur la bulle.

La taille des bulles n'a aucune importance juste une valeur ajoutée visuelle.

J'ai regardé des vidéos sur internet mais j'ai trouvé une solution manuelle, c'est-à-dire, de mettre pour chaque nom de client son étiquette, sa valeur en x, sa valeur en y et la taille de la bulle. Mais j'aimerai pouvoir faire cela de façon plus générale. Sur mon fichier, il y a une vingtaine de clients mais sur d'autres j'en ai 80 et je ne me vois pas faire ça manuellement.

Avez-vous une solution à me proposer?

Le fichier est en excel 2007 mais j'utilise excel 2013 dans mon quotidien.

Je vous remercie par avance pour votre aide,

Très bonne soirée,

Anna

PS: je mets en PJ mon fichier.

Bonjour et bonne année,

Une proposition à étudier et à adapter.

Cdlt.

Option Explicit
Dim ws As Worksheet
Dim objChart As ChartObject
'-----------------------------------------------------------
Private Sub cmdLabels_Click()
Dim lo As ListObject
Dim I As Long

    Application.ScreenUpdating = False

    Set ws = ActiveSheet
    Set lo = ws.ListObjects(1)
    Set objChart = ws.ChartObjects(1)

    With objChart.Chart
        .ApplyDataLabels Type:=xlDataLabelsShowLabel
        .SeriesCollection(1).DataLabels.Font.Size = 10
        With .SeriesCollection(1)
            For I = 1 To .Points.Count
                .Points(I).DataLabel.Characters.Text = _
                lo.ListColumns(1).DataBodyRange.Cells(I)
            Next I
        End With
    End With

    Set objChart = Nothing
    Set lo = Nothing
    Set ws = Nothing

End Sub
'-----------------------------------------------------------
Private Sub cmdReset_Click()

    Application.ScreenUpdating = False

    Set ws = ActiveSheet
    Set objChart = ws.ChartObjects(1)

    With objChart.Chart
        .ApplyDataLabels Type:=xlDataLabelsShowNone
    End With

    Set objChart = Nothing
    Set ws = Nothing

End Sub

Bonsoir Jean-Eric,

Bonne année 2016 également.

Je vous remercie pour votre aide rapide.

Je vais étudier cela de près demain.

Bonne nuit,

Anna