Gestion des index avec changement de categorie

"Bonsoir à tous. Je gère des index selon un tableau établi avec des catégories. Je rencontre des problèmes dès que le joueur passe d'une catégorie à une autre en cas de performance (voir fichier ci joint).

Ex du tournoi n°1: Le joueur part avec un Index de 13,0 en C16, il remet une carte avec un score de 36 en D16, donc il a joué son handicap (F16=0) et il est dans la ZT (score de 33 à 36), le réajustement est 0,0, son index ne change pas et sa catégorie ne change pas. Tournoi n°2: Il repart avec son nouvel index de 13,0 en I16 ou C17, il remet une carte avec un score de 33 en D17, il a donc joué 3 coups au dessus de son handicap (F17=3) et il est dans la ZT (score de 33 à 36), le réajustement est 0,0, son index ne change pas et sa catégorie ne change pas. Tournoi n°6: Il repart avec son nouvel index de 12,3 en I20 ou C21, il remet une carte avec un score de 37 en D21, il a donc réalisé une performance en jouant 1 coup de moins que son handicap (F21=-1), le réajustement à la baisse est de 0,3 (H21), son nouvel index sera de 12,3-0,3= 12,0 et sa catégorie ne change pas. Mon problème est quand le joueur réalise une performance qui le fait changer de catégorie Ex Tournoi n°7: Il repart avec son nouvel index de 12,0 en I21 ou C22, il remet une carte avec un score de 39 en D22, il a donc réalisé une performance en jouant 3 coups de moins que son handicap (F22=-3), le réajustement à la baisse est de 0,8 et non de 0,9 comme indiqué dans (H22). On doit déduire 2 pts x 0,3 = 0,6 soit 12,0-0,6 =11,4 parce que le joueur passe de la catégorie 3 à la catégorie 2, ensuite, on déduira le 3è point à 0,2 soit 11,4-(1 pt x 0,2) = 11,4-0,2 = 11,2 ce qui représente son nouvel index et non pas 11,1.

Je souhaiterais une formule qui puisse tenir compte des déductions dans le cas de changement de catégorie.

Merci pour votre aide"

Bonjour,

Un essai dont je ne sais s'il convient vraiment en entier, car tu n'as pas donné toutes les règles, tu as un tableau qui les définit, mais tu en appliques dans tes formules qui ne sont pas dans le tableau et tu ne suis pas les règles définies dans le tableau !

N'aimant pas travailler dans l'imprécision, j'ai réécrit toutes les formules pour être en confirmité avec le tableau de règles (et aussi pour les raccourcir).

En E, définition de la catégorie :

=SI(C16<>"";RECHERCHE(C16;{0;4,5;11,5;18,5;26,5;37};LIGNE($1:$6));"")

formule plus courte...

En F, le résultat par rapport à 36 :

=SI(D16<>"";SI(ESTNUM(D16);36-D16;D16);"")

Plus courte également.

En G le résultat par rapport à la ZT :

=SI(D16<>"";SI(ESTNUM(D16);SI(F16<0;F16;SI(F16>E16;F16-E16;"ZT"));D16);"")

Plus courte toujours...

En H, j'introduis une colonne, qui va apporter un correctif lorsque le résultat en G est négatif :

=SI(G16<0;MAX(-(ENT((C16-INDEX({0;4,5;11,5;18,5;26,5;37};E16))*10/E16)+1);G16);"")

Cette formule calcule le résultat de G applicable à la catégorie actuelle (en le limitant s'il y a lieu à la valeur de G, avec MAX car il s'agit de nombres négatifs). Si un écart apparaît entre la valeur en H et celle en G, l'évolution de l'index se fera sur la catégorie actuelle à partir du résultat en H, et sur la catégorie supérieure (soit chiffre inférieur) pour la différence entre G et H.

En I on trouve le réajustement, qui tient compte le cas échéant du glissement de catégorie :

=SI(D16<>"";SI(ESTNUM(G16);SI(G16<0;H16*E16/10+(E16=6)*0,4+(G16-H16)*(E16-1)/10;0,1*(E16<6));SI(G16="Dsq";0,1;0));"")

Formule entièrement refondue pour s'aligner sur ton tableau. J'ai toutefois conservé "Dsq" dont je suppose que cela signifie "disqualifié", mais pour une valeur de 0,1 car ton tableau ne prévoit pas de "malus" supérieur !

J'ai noté aussi au passage que sur la ligne notée "Abs", non explicitement prévu dans ta formule, on se voyait gratifié de 0,1 parce que "Abs" est du texte et que toute comparaison de texte avec des nombres utilisant les opérateurs > ou < renvoie toujours texte(y compris "")>nombre = VRAI. Doutant que tu aies voulu appliquer en pleine connaissance ce résultat, j'en ai déduit que là ta formule renvoyait un résultat erroné. Les autres mentions littérales n'ont pas besoin de figurer puisque la valeur 0 leur est attachée.

En J et K, formule plus courtes aussi :

=SI(D16<>"";C16+I16;"")

=SI(J16<>"";RECHERCHE(J16;{0;4,5;11,5;18,5;26,5;37};LIGNE($1:$6));"")

Cordialement.

Bonjour MFerrand

Tous mes remerciements pour ce que tu as fait. Tu m'as facilité le travail et j'ai appris de nouvelles formules. Ca me convient parfaitement. Merci

Je dois faire qlq simulations avec les autres catégories et je reviendrai vers toi

Mille merci

Abdel

Bonjour Mferrand

J'ai fait quelques simulations et petites modifications. Toutes les conditions sont respectées, c'est parfait. Il me reste deux problème à régler au niveau de la 6è Catégorie:

1- voir colonne S:S .

2- à partir d'un index 37 et plus la ZT doit disparaitre

Merci pour ton aide

Abdel

Bonjour,

J'ai du mal à suivre.

En colonne S, tu détermines que le nouvel index calculé aurait dû être 35 !

Or il est à 34, parce que tu as modifié la formule ! La formule initiale aurait bien donné 35.

Et faire disparaître la ZT, qu'est-ce que cela veut dire ?

Cordialement.

Bonsoir MFerrand

Au 7è tournoi, le joueur démarre avec un index de 37 Cat 6. Lorsqu'il a réalisé une performance -3, on devrait déduire son index de 3 pts. Comme il est près de la limite de la Cat 5, on déduit son index d'1 pt, soit 37-1=36 il passe à la catégorie 5. La déduction dans cette catégorie est de 0,5/point soit 2x0,5= 1 d'où son nouvel index est de 37-1-(2X0,5)= 35

La ZT est une marge qui permet à un joueur de garder son index initial en cas de contreperformance. Pour la Cat 6, on ne remonte pas l'index, donc pas de ZT qui apparait dans la colonne G

J'espère avoir tout dit

Merci pour ton aide et ta patience

On ne remonte pas l'index si ZT, donc cela ne change rien dans les calculs...

S'il n'y a pas ZT, il doit y avoir quoi ? (qui ne doit pas avoir d'impact sur les calculs ultérieurs.

Quant au 34, je répète : c'est ta modif qui provoque 34. Donc annule ta modif ! Il y aura 35 !