Formules

Bonjour, quelqu'un pourrait-il m'aider à effectuer sur ce tableau

les fonctions ou formules qui se font automatiquement. Voilà je fais 40h/semaine à raison de 8h/jour mais la base est de 35h/semaine donc 1h sup par jour et 5h voir plus par semaine ou je ne fais des fois que 6h par jour donc là je suis en négatif , 1h de nuit lorsque je fais 5h-13h vu que de 5h du mat à 6h l'heur est comptée de nuit ainsi que de 22h à 06h du matin, le panier qui lui est compté que l'on fasse 5h-13h ou 13h-21h du moment que 6h d'affilées son effectuées. Les CP eux sont basés sur 7h et BH (heures de récup). J'espère que ma demande est assez compréhensible et un grand merci à ceux qui pourront m'aider.

Ps : pour reporter les H sups,les CP et les Bh sur le mois suivant ainsi que les semaine comment fait-on ?

Bonjour

La cellule C7 étant sélectionnée, j'ai nommé Début la Formule

=SUBSTITUE(STXT(Juillet!$B7;1;CHERCHE(CAR(45);Juillet!$B7;1)-1);"h";":")

puis, j'ai nommé Fin la formule

=SUBSTITUE(STXT(Juillet!$B17;CHERCHE(CAR(45);Juillet!$B17;1)+1;NBCAR(Juillet!$B17));"h";":")

Suite de quoi:

Formule en C7 incrémentée vers le bas sur les jours de la semaine

=SI(OU($B7="";$B7="CP";$B7="BH";$B7="Maladie");"";MOD(Fin-Début;1))

Formule en E7 incrémentée vers le bas sur les jours de la semaine

=SI(ET(C7<>"";C7>D7);MOD(C7-D7;1);"")

Pour les heures de Nuit, formule en F7

=SI(C7="";"";(MOD(Fin-Début;1)-SI(Fin>Début;MAX(0;MIN(Fin;22/24)-MAX(Début;6/24));MAX(0;22/24-MAX(Début;6/24))+MAX(0;MIN(Fin;22/24)-6/24))))

Pour Paniers, Formule en G7

=SI(ET(C7<>"";C7>=6/24);1;"")

Pour CP, BH et Maladie, formule en H7 incrémentée sur colonnes H; I et J

=SI($B7=H$3;1;"")

Pour le No de semaine, formule en K7 (reportée ensuite par copier-coller

="Semaine "&ENT(MOD(ENT(($A7-2)/7)+0,6;52+5/28))+1

Enfin, en A3, une Formule qui renvoie le Nom de l'onglet pour adapter chaque Feuille mois

=STXT(CELLULE("nomfichier";$A$1);TROUVE("]";CELLULE("nomfichier";$A$1))+1;32)

Pour les totaux d'heures en colonne C, les cellules doivent être au format personnalisé

[h]:mm

Pour le report des heures sur le mois suivant, tu remplis les 2 Feuilles avec des chiffres et tu adapte la présentation d'Août, et tu indiques ce que tu veux voir reporté.

Cordialement

Bonjour Amadéus, pardon pour ma réponse tardive ,mais j'étais en formation à Toulouse.Tout d'abord je te remercie pour ton tableau des Heures c'est tout a fait ce que je voulait et tu est me semble t-il très compétent dans ce domaine ,mais je suis novice en la matière et je ne réussi pas à faire la manip pour faire les mois suivants de plus j'aurais voulu savoir si c'est possible, la manip à faire pour les heures en négatif car des fois je ne fais pas les heures de la journée c'est à dire que je peux travailler que 5h/jour j'ai donc 2h qui passent en "BH" (heures récup) et es que ces BH dans le tableau ,peut-on les transformer en Heures.

Merci pour tes réponses à ces nombreuses questions