Formule SOMMEPROD avec JOURSEM

Bonjour à tous,

Je fais appel aux spécialistes des formules complexes,

Voir explications dans feuille "Saisie"

en espérant que cela soit réalisable ?

Bonne journée

Amicalement

Claude

Bonjour Claude, Forum

Déjà, tu peux simplifier

=SOMMEPROD((Pain=C9)*(Pain_F)*(JOURSEM(Date;1)=JOURSEM($C$4;1)))/SOMMEPROD((JOURSEM(Date;1)=JOURSEM($C$4))*(Pain=C9))-SOMMEPROD((Pain=C9)*(Pain_i)*(JOURSEM(Date;1)=JOURSEM($C$4;1)))/SOMMEPROD((JOURSEM(Date;1)=JOURSEM($C$4))*(Pain=C9))

par

=SOMMEPROD((Pain=C9)*(Pain_F-Pain_i)*(JOURSEM(Date;1)=JOURSEM($C$4;1)))/SOMMEPROD((JOURSEM(Date;1)=JOURSEM($C$4))*(Pain=C9))

ou plus court pour ta macro (Matricielle)

=MOYENNE(SI(JOURSEM(Date;1)=JOURSEM($C$4;1)*(Pain=C9);(Pain=C9)*(Pain_F-Pain_i)))

Un peu occupé pour le moment, je regarde dès que

Amicalement..

Bonjour claude, Amadéus, forum,

Une solution dans le fichier :

Edit : Fichier modifié. Remplacement de la fonction ENT par ARRONDI.SUP pour les arrondis.

Bonjour

salut vba-new

Pour un mois précis, vba-new t'as donné la formule correcte.

Amicalement

Bonjour Amadéus, vba-new,

merci à vous deux, c'est nettement simplifié,

J'ai incorporé les %, dites-moi si correct (au niveau des parenthèses)

PS: quelle puissance, ce SOMMEPROD !

Claude

Re,

Les parenthèses sont à leurs places. Par contre, j'ai vu que l'utilisation de la fonction ENT pour arrondir n'est pas "tout le temps" bonne. Si la valeur est un entier, ça te l'arrondit à l'entier supérieur. Tu peux utiliser à la place la fonction ARRONDI.SUP.

Les formules corrigées :

En D8 :

=ARRONDI.SUP(SOMMEPROD((Pain=$C8)*(Pain_F-Pain_i)*(JOURSEM(Date)=JOURSEM($C$4)))/SOMMEPROD((Pain=$C8)*(JOURSEM(Date)=JOURSEM($C$4)));0)

En E8 :

=ARRONDI.SUP(SOMMEPROD((Pain=$C8)*(Pain_F-Pain_i)*(JOURSEM(Date)=JOURSEM($C$4)))/SOMMEPROD((Pain=$C8)*(JOURSEM(Date)=JOURSEM($C$4)))*(1+$C$2);0)

En G8 :

=ARRONDI.SUP(SOMMEPROD((Pain=$C8)*(Pain_F-Pain_i)*(JOURSEM(Date)=JOURSEM($C$4))*(MOIS(Date)=MOIS($C$4)))/SOMMEPROD((Pain=$C8)*(JOURSEM(Date)=JOURSEM($C$4))*(MOIS(Date)=MOIS($C$4)))*(1+$C$2);0)

re,

Ok, c'est corrigé

encore merci et bonne journée

Amicalement

Claude