Formule SI et ET
Bonjour,
Je souhaiterais une formule excel qui correspond dans mon onglet "besoin global" à la somme la plus grande entre "besoin par espace journee" et "besoin par espace soiree" mais qui ignore les valeurs en face de "cuisine centrale"
Exemple : Dans l'onglet Besoin global ; pour le code 825502 au 1928 je devrais trouver le chiffre 400.
Merci par avance de votre aide
Bonjour et bienvenue sur le forum,
Quelle version d'Excel utilisez-vous ? 2016/2021/... 365 ?
Précisez-le sur votre profil, cela permettra de vous donner une formule adaptée à votre version.
Quand vous dites "les valeurs en face de cuisine centrale", vous vous référez à l'onglet "Club des loges" c'est bien ça ?
J'utilise Excel 365. Oui tout à fait, à l'onglet Club des loges.
Ok parfait, n'oubliez pas de mettre à jour votre profil (section "version") pour 365 FR.
Une proposition :
Feuille "besoin par espace journée" cellule D5 (à tirer vers le bas) :
=SOMME.SI.ENS('CLUB DES LOGES'!$J$6:$J$115; 'CLUB DES LOGES'!$F$6:$F$115;$B5; 'CLUB DES LOGES'!$G$6:$G$115;"<>"&'CLUB DES LOGES'!$C$191)Feuille "besoin par espace soirée" cellule D5 (à tirer vers le bas) :
=SOMME.SI.ENS('CLUB DES LOGES'!$J$117:$J$166; 'CLUB DES LOGES'!$F$117:$F$166;$B5; 'CLUB DES LOGES'!$G$117:$G$166;"<>"&'CLUB DES LOGES'!$C$191)Feuille "besoin global" cellule D5 (à tirer vers le bas) :
=MAX(RECHERCHEX(B5;'BESOIN PAR ESPACE JOURNEE'!B:B;'BESOIN PAR ESPACE JOURNEE'!D:D);RECHERCHEX(B5;'BESOIN PAR ESPACE SOIREE'!B:B;'BESOIN PAR ESPACE SOIREE'!D:D))Notez : j'ai préféré utiliser RECHERCHEX afin de s'assurer qu'on regroupe bien par "ID" car si jamais vous insériez une ligne dans une feuille et pas l'autre, cela pourrait tout chambouler.
Je vous remercie les formules fonctionnes parfaitement !!
J'ai besoin d'ajouter les valeurs de J de 169 à 186 dans mon besoin global, est ce possible d'ajouter à la formule un element ?
Bien sûr, il suffit d'ajouter au résultat précédent la RECHERCHEX sur cette colonne, soit :
=MAX(
RECHERCHEX(B5;'BESOIN PAR ESPACE JOURNEE'!B:B;'BESOIN PAR ESPACE JOURNEE'!D:D);
RECHERCHEX(B5;'BESOIN PAR ESPACE SOIREE'!B:B;'BESOIN PAR ESPACE SOIREE'!D:D)
) + RECHERCHEX(B5;'CLUB DES LOGES'!$F$170:$F$186;'CLUB DES LOGES'!$J$170:$J$186;0)
N'oubliez pas de passer le sujet en résolu si tout est bon pour vous.
EDIT : puisque ces lignes comptent des duplicata, RECHERCHEX ne va pas. Il faut plutôt utiliser SOMME.SI, soit :
=MAX(
RECHERCHEX(B5;'BESOIN PAR ESPACE JOURNEE'!B:B;'BESOIN PAR ESPACE JOURNEE'!D:D);
RECHERCHEX(B5;'BESOIN PAR ESPACE SOIREE'!B:B;'BESOIN PAR ESPACE SOIREE'!D:D)
) + SOMME.SI('CLUB DES LOGES'!$F$170:$F$186;B5;'CLUB DES LOGES'!$J$170:$J$186)Je vous en prie, pour cloturer le sujet :