Fond de couleur sur feuille protégée

Bonjour le forum,

Ma macro fonctionne correctement si la feuille n'est pas protégée mais ne fonctionne pas lorsque celle ci est protégée. Elle met bien en vert ma sélection (simple ou multiple)

Sub fondvert()

With Selection.Interior

.ColorIndex = 4

.Pattern = xlSolid

.PatternColorIndex = xlAutomatic

End With

End Sub

comment avoir l'équivalent qui fonctionne sur ma feuille protégée par MDP (cellule déverrouillées)

https://www.excel-pratique.com/~files/doc/fond.xls

merci

Bonjour

commence ta macro par cela

ActiveWorkbook.Unprotect Password:="mot de passe"

ActiveSheet.Unprotect Password:="mot de passe"

et fini par cela

ActiveSheet.Protect Password:="mot de passe"

ActiveWorkbook.Protect Password:="mot de passe"

protection de la feuille et protection du classeur

laurent

C'est une bonne solution sauf que rien n'est protégé dans ce cas...

Les cellules vérouillées ne servent plus.

merci

re

la macro déverouille en se déclenchant et revérouille après, ca ne va pas?

sinon, a mon avis pas de solution mais peut-etre que quelqu'un d'autre a une solution

laurent

La macro fonctionne très bien mais les endroits où les cellules sont vérouillées il est possible

de lancer la macro dessus...

Merci

re

c'est a dire reverouiller que certaine cellules?

cette macro dévérouille tout et revérouille tout

interessant mais je n'ai jamais essayer, mes capacité sont limitées

peut-être que les "pros" de ce forum sauront répondre, dans ce cas cela m'interesserais également.

Laurent

Salut,

Si tu veux que cela se fasse avec la protection des cellules, essaies en faisant ceci lorsque tu verrouilles ta feuille:

A te lire,

Souri84

Edit2:

Sinon par macro:

    ActiveSheet.Protect DrawingObjects:=False, Contents:=True, Scenarios:= _
        False, AllowFormattingCells:=True

re:

laurent

Cela fonctionne mais aussi sur les cellules verrouillées

Je souhaite mettre un fond vert via une macro que sur des cellules non verrouillées (avec protection par MDP) les autres ne doivent pas être modifiées!

ci joint : https://www.excel-pratique.com/~files/doc/fond2.xls

merci

Re:

la solution que j'ai trouvé:

avant de vérouiller: tu met une mise en forme conditionnelle sur les cellules que tu veux vérouiller du genre:

si valeur est différent de : azertyui :alors couleur de fond noir

ensuite tu vérouille en autorisant : format de cellule

et voila, meme en selectionnant les case noir et en lancant ta macro, les cellules noir resteront noir.

laurent

Bonsoir,

En autorisant "Format de cellule" à la protection :

Sub fondvert()
Dim cel As Range

For Each cel In Selection
    If Not cel.Locked = True Then
    With cel.Interior
    .ColorIndex = 4
    .Pattern = xlSolid
    .PatternColorIndex = xlAutomatic
    End With
    End If
Next cel

End Sub

La macro ne coloriera pas les cellules verrouillées, mais tu peux le faire manuellement...

A mi-chemin de ce que tu voulais, mais apparemment pas mieux à faire, même sur 2007...

re:

et si on fusionne les deux solutions,

avec ta macro et une mise en forme conditionnelle "impossible a reproduire" comme dans mon precedent message, même manuellement, ce serat impossible?

Peut-etre dij-je une bêtise mais ça me parait être une bonne solution non?

Laurent

Salut le forum

Un bout de code qui fonctionne que sur une selection de cellules non vérouillées.

Il faut dire à Excel qu'il est maître à bord avec UserInterfaceOnly:=True

Dim Cellule As Range 'A placer en début du module

Sub Nep()
ActiveSheet.Protect Password:="12345", UserInterfaceOnly:=True
    For Each Cellule In Selection
        With Cellule
            If .Locked = False Then
            .Interior.ColorIndex = 4
            End If
        End With
    Next Cellule
End Sub

Sub AnnuleNep()
ActiveSheet.Protect Password:="12345", UserInterfaceOnly:=True
    For Each Cellule In Selection
        With Cellule
            If .Locked = False Then
            .Interior.ColorIndex = 15
            End If
        End With
    Next Cellule
End Sub

Mytå

cela fonctionne super bien !

Merci