Fonctions logiques trop complexes?
Bonjour forum,
j'ai 2 colonnes dont les valeurs des cellules peuvent être représentées par 5 catégories: n, s, rs, r, z dans chacune des colonnes. La combinaison des valeurs des 2 colonnes donne 25 combinaisons possibles dont le résultat peut être de: 0 5 10 et 20. Pour attribuer les valeurs aux combinaisons, j'ai tenté d'utiliser des formules logiques: SI, ET, OU.
Cependant, je dois admettre que ma logique (ou mes formules, ou les deux) font défaut car je n'obtiens pas ce que je devrais m'attendre. Je fournis un fichier avec un tableau de 5 x 5 qui donne les 25 valeurs attendues des possibilités de combinaisons. Si, il y a une façon plus élégante de solutionner ce problème, je suis preneur.
Je vous remercie d'avance
Michel
Bonjour,
=SI(A2=B2;0;SI(OU(A2="z";B2="z");20;SI(OU(ET(OU(A2="r";A2="s");B2="rs");ET(OU(B2="r";B2="s");A2="rs"));5;10)))Cordialement.
bonjour,
Je préfère cette formulation que je trouve plus lisible :
=SI(A2=B2;0;
SI(OU(A2="z";B2="z");20;
SI(ET(A2="n";B2="r");10;
SI(ET(A2="n";B2="rs");10;
SI(ET(A2="n";B2="s");10;
SI(ET(A2="r";B2="n");10;
SI(ET(A2="r";B2="rs");5;
SI(ET(A2="r";B2="s");10;
SI(ET(A2="rs";B2="n");10;
SI(ET(A2="rs";B2="r");5;
SI(ET(A2="rs";B2="s");5;
SI(ET(A2="s";B2="n");10;
SI(ET(A2="s";B2="r");10;
SI(ET(A2="s";B2="rs");5;"erreur"))))))))))))))Joyeuses fêtes !
A+
Salut Michel,
Bonjour MFerrand, Galopin,
pour le plaisir de faire autrement...
=SI(A2=B2;0;SI(OU(A2="z";B2="z");20;SI(OU(ET(DROITE(A2;1)="s";DROITE(B2;1)="s");ET(GAUCHE(A2;1)="r";GAUCHE(B2;1)="r"));5;10)))Joyeuses Fêtes!
A+
Bonjour à toutes et tous,
Comme j'ai l'esprit tordu, je n'ais pas compris la même chose
Du coup voici une proposition:
Plage de cellules "F4:J8"
Cordialement.
Bonjour à vous trois,
toutes vos solutions fonctionnent bien. Quant à moi, je réalise que je n'avais pas complètement bien saisi toute la syntaxe parfaite pour bien appliquer les combinaisons de ET/OU dans les formules.
Je vous remercie encore et
Joyeuses Fêtes à vous,
Michel
Bonsoir,
Salut mdo ! J'avais failli faire comme toi au départ !
Une autre qui m'a l'air légèrement plus courte :
=SI(A2=B2;0;SI(OU(A2="z";B2="z");20;SI(OU(A2="n";B2="n");10;SI(OU(A2="rs";B2="rs");5;10))))Cordialement.