Fonction Vlookup inversé

Bonsoir à tous,

Tout est dit dans le titre. Je souhaite faire une rechercheV en vba avec Vlookup mais je veux obtenir la valeur situé dans la cellule immédiatement à gauche?

Mon code actuel (qui ne marche pas):

ThisWorkbook.Worksheets("FL").Range("E23") = Application.WorksheetFunction.VLookup(ThisWorkbook.Worksheets("FL").Range("K23"), ThisWorkbook.Worksheets("Temporaire").Range("B7:B27"), 1 And Offset(0, -1), False)

Je cherche la valeur de E23 de la feuille "FL", dans la colonne B de ma feuille "Temporaire", pour pouvoir renvoyer la valeur contenue dans la colonne A. J'ai pensé à l'offset 0,-1 mais je dois surement mal l'utiliser ...

Merci d'avance pour votre aide.

Cordialement,

Corsaire

Bonsoir,

Une proposition ci dessous.

Mais cependant attention, étant donné qu'il n'y a pas de fichier et que nous ne savons pas s'il y a des doublons ou pas...

J'ai mis le résultat dans un msgbox puisque nul part vous dites quoi en faire.

Sub cherche()
Dim i As Long

With Sheets("Temporaire")
    For i = 1 To .Range("B" & .Rows.Count).End(xlUp).Row
        If Sheets("FL").Cells(23, 5) = .Cells(i, 2) Then
            MsgBox .Cells(i, 1)
        End If
    Next i
End With
End Sub

ou avec le offset pour vous montrer son utilisation :

Sub cherche()
Dim i As Long

With Sheets("Temporaire")
    For i = 1 To .Range("B" & .Rows.Count).End(xlUp).Row
        If Sheets("FL").Cells(23, 5) = .Cells(i, 2) Then
            MsgBox .Cells(i, 2).Offset(, -1)
        End If
    Next i
End With
End Sub

Bonjour,

Une solution qui s’apparente à une recherche avec INDEX + EQUIV

Sub Test()
Dim Ligne As Long
    With Worksheets("FL")
        'On relève la position de la valeur de FL!K23 dans Temporaire!B7:B27
        Ligne = Application.Match(.Range("K23"), Worksheets("Temporaire").Range("B7:B27"), 0)
        'On renvoie dans FL!E23 la valeur contenue sur cette même ligne dans Temporaire!A7:A27
        .Range("E23") = Worksheets("Temporaire").Range("A7:B27").Cells(Ligne, 1)
    End With
End Sub 

A+

Bonjour à vous deux,

Merci pour votre aide, tout fonctionne parfaitement grâce à vous !

Cordialement,

Corsaire