Exporter en PDF chaque feuilles dans son propre dossier

Bonjour,

Je cherche à exporter en PDF chaque feuilles créées dans un dossier différent, est possible ?

En clair : la feuille "1135" dans le "U:\COMMUN\1135 - Lycée PMF - VILLIERS LE BEL"

ou encore : la feuille "1131" dans le "U:\COMMUN\1131 - QUERQUEVILLE"

Et ce pour chaque feuilles générées par ma première macro. (Merci ThauThème)

Je joins le fichier.

Merci d'avance.

Bonjour Romain50,

un exemple à tester

Sub testRomain50()

Dim MyFolder As String, MySubFolder As String, MyFile As String
Dim ws As Worksheet

Application.ScreenUpdating = False

    For Each ws In ThisWorkbook.Worksheets

        If ws.Name <> "INFO" Then

        MyFolder = "U:\COMMUN\"
        MySubFolder = Dir("U:\COMMUN\" & ws.Name & "*", vbDirectory) & "\"
        MyFile = ws.Name & ".pdf"

        MyFile = MyFolder & MySubFolder & MyFile

        ws.ExportAsFixedFormat _
                Type:=xlTypePDF, _
                Filename:=MyFile, _
                Quality:=xlQualityStandard, _
                IncludeDocProperties:=True, _
                IgnorePrintAreas:=False, _
                OpenAfterPublish:=False

        End If

    Next ws

Application.ScreenUpdating = True

End Sub

Si tu souhaite exclure d'autres feuilles de l'exportation, tu peux modifier cette ligne

If ws.Name <> "INFO" Or ws.Name <> "Feuil1" Then

Cordialement

Bonjour Sequoyah,

Merci beaucoup c'est super ! Mais je n'avais pas penser à 2 choses ! Est il possible que chaque PDF soit nommer comme tu me l'as fait c'est à dire "1123" ou "1129" mais en ajoutant le mois et l'année ? exemple "1123 09/22" ou "1129 09/22"

De plus est il possible de mettre un format automatiquement en paysage pour le PDF ?

Par avance merci à toi si tu peux !

Bonne journée.

Bonjour Romain50

Tu peux remplacer la ligne : MyFile = ws.Name & ".pdf"

Par la ligne : MyFile = ws.Name & Format(Now(), "mm_yy") & ".pdf"

Salut le fil

De plus est-il possible de mettre un format automatiquement en paysage pour le PDF ?

Pour se faire tu dois utiliser La propriété Orientation de l'objet PageSetup ce qui te donne

' ...
        If ws.Name <> "INFO" Then
            With ws
                ' // Ici tu gères tes propriétés
                ' ...
                .PageSetup.Orientation = xlLandscape
                '...
            End With
'...
'...

Bonjour le fil,

Merci à vous cela fonctionne super !

Bonne journée à tous !

Salut Romain,

Content que l'on ait pu t'aider.

juste une petite reflexion, dans tes feuilles Excel si tu paramètres ton impression sur paysage, elles s'imprimerons dans cette orientation même sur un export en PDF. Ceci t'évite de rajouter du code... 😉

Salut Jean-Paul,

Bon à savoir ! Merci !