Etendre fonction double clique

Bonjour à tous.

J’utilise souvent la fonction "RECHERCHEV". Je fais un double clique sur ma 1ère cellule pour que la fonction s'étende jusqu'à ma dernière ligne de tableau (dans l'exemple ci-dessous = 11375).

Comment modifier ma macro VBA pour que lorsque je fait mon double clique sur la 1ère cellule, l'extension de la fonction s'arrête automatiquement à la dernière ligne, car le nombre de ligne de mon tableau peut varier ?

Et comment faire pour que ça le fasse à chaque fois que j'utilise "RECHERCHEV" (dans l'exemple ci-dessous = utilisée 2 fois) ?

J'ai un début de piste avec quelque chose comme ça -" Lastrow = Cells(65536, 1).End(xlUp).Row " -, mais je ne sais pas comment l'utiliser et l'insérer dans ma macro ci-dessous.

Sub ARTICLE_INFO()

'

' ARTICLE_INFO Macro

'

'

ActiveCell.FormulaR1C1 = "=VLOOKUP(RC[-1],'AL010'!R2C2:R11705C3,2,0)"

Selection.AutoFill Destination:=Range("E2:E11375")

Range("E2:E11375").Select

Columns("F:F").Select

Selection.Insert Shift:=xlToRight, CopyOrigin:=xlFormatFromLeftOrAbove

Range("F1").Select

ActiveCell.FormulaR1C1 = "SGF"

With ActiveCell.Characters(Start:=1, Length:=3).Font

.Name = "Verdana"

.FontStyle = "Gras"

.Size = 8

.Strikethrough = False

.Superscript = False

.Subscript = False

.OutlineFont = False

.Shadow = False

.Underline = xlUnderlineStyleNone

.ColorIndex = xlAutomatic

.TintAndShade = 0

.ThemeFont = xlThemeFontNone

End With

Range("F2").Select

ActiveCell.FormulaR1C1 = "=VLOOKUP(RC[-2],'ST200'!R2C3:R1576C7,5,0)"

Selection.AutoFill Destination:=Range("F2:F11375")

Range("F2:F11375").Select

Range("F1").Select

End Sub

Merci d'avance pour vos infos.

Bonsoir

A tester

Sub ARTICLE_INFO()
' ARTICLE_INFO Macro
Dim Nblg As Long

  Nblg = Range("A" & Rows.Count).End(xlUp).Row
  Columns("F").Insert
  With Range("F1")
    .Value = "SGF"
    With .Font
      .Name = "Verdana"
      .FontStyle = "Gras"
      .Size = 8
      .Strikethrough = False
      .Superscript = False
      .Subscript = False
      .OutlineFont = False
      .Shadow = False
      .Underline = xlUnderlineStyleNone
      .ColorIndex = xlAutomatic
      .TintAndShade = 0
      .ThemeFont = xlThemeFontNone
    End With
  End With
  Range("E2").Formula = "=VLOOKUP(D2,'AL010'!B2:C11705,2,0)"
  Range("F2").Formula = "=VLOOKUP(D2,'ST200'!C2:G1576,5,0)"
  Range("E2:F2").AutoFill Range("E2:F" & Nblg), xlFillSeries
End Sub

Avec un fichier cela serait mieux

Merci Banzaï, c'est exactement ce que je voulais. ça marche nickel !