Envoi Email au format PDF

Bonjour, je travail sur ce code, car j'aimerais envoyer un email à plusieurs destinataires en format PDF de A1 à L55 uniquement car pour l'instant cela joint le fichier en entier et ce n'est pas ce que je souhaite ( je veux uniquement une sélection de A1 à L55).

Merci pour votre aide

Sub SendMail_Outlook()

Dim OL As Object

Dim OLmail As Object

Dim Texte As String

Set OL = CreateObject("Outlook.Application")

Set OLmail = OL.CreateItem(0)

Texte = "Nice, le " & Format(Date, "dd/mm/yy") & vbCrLf & vbCrLf

Texte = Texte & "Madame, Monsieur" & vbCrLf

Texte = Texte & vbCrLf

Texte = Texte & "Objet: Enlèvement bouteilles de gaz déchetterie Nice Est" & vbCrLf & vbCrLf

Texte = Texte & "Vous voudrez bien trouver ci-joint le nouvel état du stock. " & _

"Pour des raisons de sécurité, je vous demande de prévoir un enlèvement au plus tôt." & vbCrLf & vbCrLf

Texte = Texte & "Merci de bien vouloir collecter le reliquat éventuel et de nous préciser une date d'intervention par retour de mail" & vbCrLf & vbCrLf

Texte = Texte & vbCrLf

Texte = Texte & "Dans l'attente, salutations cordiales" & vbCrLf

With OLmail

.To = [T1] 'adresse du destinataire en T1

.CC = [T3]

.Subject = "BOUTEILLES DE GAZ NICE EST"

.Attachments.Add ThisWorkbook.Path & "\" & ThisWorkbook.Name

.Body = Texte

.Display

.Send 'envoi automatique

End With

'Désactivation sélection

Application.CutCopyMode = False

End Sub

bonjour

essaie ceci

Range("A1:L55").ExportAsFixedFormat Type:=xlTypePDF, Filename:=ThisWorkbook.Path & "\attachment.pdf"
        .Attachments.Add ThisWorkbook.Path & "\attachment.pdf"

Merci, mais a qu'elle hauteur je le colle dans mon code.

bonjour,

tu remplaces ta ligne

attachments.add

par les 2 lignes fournies

J'ai bien fais le remplacement, mais j'ai un message d'erreur

bonjour,

voici le code adapté

Sub SendMail_Outlook()

Dim OL As Object
Dim OLmail As Object
Dim Texte As String

Set OL = CreateObject("Outlook.Application")
Set OLmail = OL.CreateItem(0)

Texte = "Nice, le " & Format(Date, "dd/mm/yy") & vbCrLf & vbCrLf
Texte = Texte & "Madame, Monsieur" & vbCrLf
Texte = Texte & vbCrLf
Texte = Texte & "Objet: Enlèvement bouteilles de gaz déchetterie Nice Est" & vbCrLf & vbCrLf
Texte = Texte & "Vous voudrez bien trouver ci-joint le nouvel état du stock. " & _
"Pour des raisons de sécurité, je vous demande de prévoir un enlèvement au plus tôt." & vbCrLf & vbCrLf
Texte = Texte & "Merci de bien vouloir collecter le reliquat éventuel et de nous préciser une date d'intervention par retour de mail" & vbCrLf & vbCrLf

Texte = Texte & vbCrLf

Texte = Texte & "Dans l'attente, salutations cordiales" & vbCrLf

With OLmail

.To = [T1] 'adresse du destinataire en T1
.CC = [T3]
.Subject = "BOUTEILLES DE GAZ NICE EST"
Range("A1:L55").ExportAsFixedFormat Type:=xlTypePDF, Filename:=ThisWorkbook.Path & "\attachment.pdf"
        .Attachments.Add ThisWorkbook.Path & "\attachment.pdf"
.Body = Texte
.Display
.Send 'envoi automatique

End With

'Désactivation sélection
Application.CutCopyMode = False

End Sub

Est-il possible que dans le fichier joint, ce dernier porte également la date de l'envoi sur la ligne de code suivante

Range("A1:L55").ExportAsFixedFormat Type:=xlTypePDF, Filename:=ThisWorkbook.Path & "\attachment.pdf"

.Attachments.Add ThisWorkbook.Path & "\attachment.pdf"

.Body = Texte

.Display

.Send 'envoi automatique

Ceci me permettant de faciliter le classement des éléments envoyer.

Comme par exemple "attachment dd-mm-aa"

Merci

bonjour,

une correction pour metre la date dans le nom du fichier pdf

Sub SendMail_Outlook()

    Dim OL As Object
    Dim OLmail As Object
    Dim Texte As String

    Set OL = CreateObject("Outlook.Application")
    Set OLmail = OL.CreateItem(0)

    Texte = "Nice, le " & Format(Date, "dd/mm/yy") & vbCrLf & vbCrLf
    Texte = Texte & "Madame, Monsieur" & vbCrLf
    Texte = Texte & vbCrLf
    Texte = Texte & "Objet: Enlèvement bouteilles de gaz déchetterie Nice Est" & vbCrLf & vbCrLf
    Texte = Texte & "Vous voudrez bien trouver ci-joint le nouvel état du stock. " & _
            "Pour des raisons de sécurité, je vous demande de prévoir un enlèvement au plus tôt." & vbCrLf & vbCrLf
    Texte = Texte & "Merci de bien vouloir collecter le reliquat éventuel et de nous préciser une date d'intervention par retour de mail" & vbCrLf & vbCrLf

    Texte = Texte & vbCrLf

    Texte = Texte & "Dans l'attente, salutations cordiales" & vbCrLf

    With OLmail

        .To = [T1]    'adresse du destinataire en T1
        .CC = [T3]
        .Subject = "BOUTEILLES DE GAZ NICE EST"
        fichier = ThisWorkbook.Path & "\attachment" & Format(Date, "yyyymmdd") & ".pdf"
        Range("A1:L55").ExportAsFixedFormat Type:=xlTypePDF, Filename:=fichier
        .Attachments.Add fichier
        .Body = Texte
        .Display
        .Send    'envoi automatique

    End With

    'Désactivation sélection
    Application.CutCopyMode = False

End Sub

Merci, mais après avoir intégré ton code, il y a un message d'erreur de compilation avec le mot fichier qui est surligné

Bonjour,

tu as l'option explicit, ce qui oblige à définir les variables. (ce qui est une bonne pratique, que je ne fais pas).

ajoute une instruction

Dim fichier As String

à la suite des autres instructions Dim