Enregistre la feuille active seulement avec un nom spécifique

bonjour à tous

j'ai établie une macro pour sauvegarder ma feuille active en pdf mais je n'ai pas pu faire la même chose pour le format xls

Pouvez vous m'aider SVP

fichier joint

code :

Sub Bouton5_Cliquer()

Dim cheminAcces As String

Dim reponse As Integer

cheminAcces = "C:\Users\sassi.sghaier\Desktop\PROJET FACTURATION\"

reponse = MsgBox("désirez-vous sauvgarder la facture ?", vbQuestion + vbYesNo, "Entegistrement")

If reponse = vbYes Then

Feuil1.ExportAsFixedFormat xlTypePDF, cheminAcces & Feuil1.Range("e11").Value & " " & Feuil1.Range("e10").Value & ".pdf", xlQualityStandard, _

True, False, , , True

MsgBox "votre facture a été sauvguardéé", vbOKOnly + vbInformation, "SAUVGUARDE"

Else

Exit Sub

End If

End Sub

Bonjour,

Pas bien compris ! Tu veux enregistrer ta facture en fichier .xlsx autonome ?

Si c'est le cas il faut copier la feuille dans un nouveau classeur et enregistrer ce dernier !

Cordialement.

salut pas du tout

dans mon macro j'ai pu enregistrer la feuille active en PDF je veux faire la même chose en xlsx dans le même macro

sheetactive.saveas il m'enregistre tout le classeur, or je veux seulement la feuille

merci

As-tu lu ce que j'ai écrit ?

oui

mais je suis nul en vba

si vous pouvez me donner la solution en ligne de code

le nom du fichier doit être comme celui de pdf mais en Excel

merci merci

Salut Sassi,

voici le code:

Sub Bouton6_Cliquer()

    Dim wb As Workbook
    Dim cheminAcces As String
    Dim reponse As Integer

    cheminAcces = "C:\Users\sassi.sghaier\Desktop\PROJET FACTURATION\"

    reponse = MsgBox("Désirez-vous sauvegarder la facture?", vbQuestion + vbYesNo, "Enregistrement")
    If reponse = vbYes Then

        Sheets("Facture").Copy

        Set wb = ActiveWorkbook

        With wb
            .SaveAs cheminAcces & Sheets("Facture").Range("e11").Value & " " & Sheets("Facture").Range("e10").Value & ".xlsx"
            .Close False
        End With
        MsgBox "Votre facture a été sauvegardée", vbOKOnly + vbInformation, "SAUVEGARDE"

    Else

        Exit Sub

    End If

End Sub

super 1000 merci

juste une chose comment faire pour que les bottons ne figure pas dans la feuille xlsx?

et il possible d’intégrer ce code avec le boton du pdf?

merci

Voilà :

Sub Bouton5_Cliquer()
    Dim cheminAcces As String, fichier As String, reponse As Integer
    'cheminAcces = "C:\Users\sassi.sghaier\Desktop\PROJET FACTURATION\"
    cheminAcces = "E:\Documents\"
    reponse = MsgBox("désirez-vous sauvgarder la facture ?", vbQuestion + vbYesNo, "Entegistrement")
    If reponse = vbYes Then
        With Feuil1
            fichier = .Range("e11").Value & " " & .Range("e10").Value & ".pdf"
            .ExportAsFixedFormat xlTypePDF, cheminAcces & fichier, OpenAfterPublish:=True
            fichier = Replace(fichier, ".pdf", ".xlsx")
            .Copy
        End With
        ActiveWorkbook.SaveAs cheminAcces & fichier
        MsgBox "Votre facture a été sauvegardée", vbInformation, "SAUVEGARDE"
    End If
End Sub

Cordialement.

MERCI BIEN C VRAIMENT MAGIQUE HHHHH

UNE SEUL CHOSE COMMENT FAIRE POUR QUE LES BOUTON NE FIGURE PAS DANS LA NOUVELLE FEUILLE EXCEL ?

OK ! Je te revoie ça, mais après manger !!!

MERCI ET BON APPETIT

PAR LA MÊME OCCASION Y A T IL LA POSSIBILITÉ QUE LA COPIE TRANSFORME LES CHAMPS EN VALEUR ( POUR QU'IL NE CHANGE PAS SE SONT DES CELLULES LIÉES )

MERCI

salut MFerrand

j'attends toujours que tu finis ton assiette

Sassi a écrit :

MERCI ET BON APPETIT

PAR LA MÊME OCCASION Y A T IL LA POSSIBILITÉ QUE LA COPIE TRANSFORME LES CHAMPS EN VALEUR ( POUR QU'IL NE CHANGE PAS SE SONT DES CELLULES LIÉES )

MERCI

Pas crier ! Ça n'ira pas plus vite !

Sub Bouton5_Cliquer()
    Dim cheminAcces As String, nomFichier As String, reponse As Integer, shp As Shape
    reponse = MsgBox("désirez-vous sauvegarder la facture ?", vbQuestion + vbYesNo, _
     "Enregistrement")
    If reponse = vbNo Then Exit Sub
    Application.ScreenUpdating = False
    cheminAcces = "C:\Users\sassi.sghaier\Desktop\PROJET FACTURATION\"
    Feuil1.Copy before:=Worksheets(1)
    With Worksheets(1)
        .Range("B9:E42").Value = .Range("B9:E42").Value
        For Each shp In .Shapes
            shp.Delete
        Next shp
        .Columns("G:K").Delete
        nomFichier = .Range("E11") & " " & .Range("E10") & ".xlsx"
        .Move
    End With
    With ActiveWorkbook
        .Worksheets(1).Name = "Facture"
        .SaveAs cheminAcces & nomFichier
        nomFichier = Replace(nomFichier, ".xlsx", ".pdf")
        MsgBox "Votre facture a été sauvegardée", vbInformation, "SAUVEGARDE"
        .Worksheets(1).ExportAsFixedFormat xlTypePDF, cheminAcces & nomFichier, _
         OpenAfterPublish:=True
    End With
End Sub

Cordialement.

bonjour

merci c'est exactement ce que je veux

tu est un génie