Dossiers et sous dossiers

Bonjour à Toutes et à tous,

Malgré toutes mes tentatives je n'arrive pas à m'en sortir. Je commence même à mélanger les commandes!!!

J'ai plusieurs fichiers Excel et j'aimerais pouvoir générer à chaque fois un fichier pdf à partir du fichier actif mais l'enregistrement du fichier devrait se faire dans un répertoire bien spécifique. C'est à dire, à chaque fois que j'imprime au format Pdf, le fichier prend le nom qui est dans la cellule F2 et la cellule R2, puis devrait être sauvé dans le répertoire qui a l'intitulé de la cellule F2 en vérifiant que le répertoire existe sinon il doit le créer et si le document existe me demander si je veux l’écraser ou non.

J'espère que mon message est assez clair!!!

Merci d'avance pour toute aide

Bonjour

sans fichier difficile de t'aider...

mais voici un exemple de code que j'avais fait il y a quelques temps qui imposait le nom du sous repertoire "Export_PDF" a adapter donc

fred

'--------------------------------------------------------------------------------------------------
'Nécessite d'activer la référence "Microsoft Scripting RunTime" dans l'éditeur de macros (Alt+F11):
'Menu Outils\Références
'Cochez la ligne "Microsoft Scripting RunTime". Cliquez sur le bouton OK pour valider.
'--------------------------------------------------------------------------------------------------

Sub tester_et_enregistrer()
Dim chemin As String
Dim nom As String
Dim monfichier As String
Dim monfichierPDF As String

chemin = ActiveWorkbook.Path & "\"
monfichier = ActiveWorkbook.Name
    test_repertoire (chemin)                                                        ' création d 'un repertoire export_pdf si il n'existe pas
    monfichierPDF = [F2].value & [R2].value & ".pdf"
    enregistrement (chemin & "Export_PDF\" & monfichierPDF)   ' enregistrement au format pdf du fichier

End Sub
Sub test_repertoire(chemin As String)
Dim fs As Scripting.FileSystemObject

Set fs = CreateObject("Scripting.FileSystemObject")                                 ' initialisation de la variable

If fs.FolderExists(chemin & "Export_PDF") Then                                      ' le repertoire existe donc rien a faire
Else: fs.CreateFolder chemin & "export_PDF"                                         ' le repertoire n'existe pas donc on le créer
End If
Set fs = Nothing
End Sub
Sub enregistrement(fichier_destination As String)
ActiveWorkbook.ExportAsFixedFormat Type:=xlTypePDF, Filename:=fichier_destination, Quality:=xlQualityStandard, _
IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False        ' sauvegarde du fichier au format pdf
End Sub

Chapeau bas Fred,

Cela marche à merveille, mille bravos !!!!

Juste un minimum d'adaptation pour mon code et c'est un bijou à garder précieusement.

Merci encore.