Créer une liste déroulante en fonction du jour de la sem et du jour férié

Bonjour,

J'ai un soucis lors de la création d'une liste déroulante. Je suis arrivé en fonction du jour de la semaine à afficher une liste déroulante dans les cellule A2 à I20. Mais je n'arrive pas à intégrer la liste déroulante correspondant au jour férié. Car si c'est un jour Férié alors la liste Férié primo devant les autres.

J'ai intégré cette formule dans la validation des données, mais lorsque j'essais de mettre en 1er la formule "SI(A$1=JFeries!$A$1:$U$11;FERIE" avec le jour férié ça ne fonctionne pas. Je pense qu'il me manque quelque chose ou que j'écris vraiment mal la formule.

SI(TEXTE(A$1;"jjjj")="Lundi";LU;SI(TEXTE(A$1;"jjjj")="Mardi";MA;SI(TEXTE(A$1;"jjjj")="Mercredi";ME;SI(OU(TEXTE(A$1;"jjjj")="Jeudi";TEXTE(A$1;"jjjj")="Vendredi";TEXTE(A$1;"jjjj")="Samedi");JE_VE_SA;NORMAL))))

Merci de votre aide

Bonjour,

Une proposition de formule à tester :

=SI(NB.SI(JFeries!$B$2:$U$11;A$1)>0;FERIE;CHOISIR(JOURSEM(A$1;2);LU;MA;ME;JE_VE_SA;JE_VE_SA;JE_VE_SA;NORMAL))

C'est juste parfait, c'est ce que je voulais

Est-ce qu'il possible d'ajouter une autre variante, c'est-à dire qu'en fonction du jour férié il affiche une liste déroulante différente et si ce n'est pas un jour férié il affiche ce qui était avant dans ta formule :

• Si le jour férié tombe un lundi alors liste déroulante LU_FERIE
• Si le jour férié tombe un mardi alors liste déroulante MA_FERIE
• Si le jour férié tombe un mercredi alors liste déroulante ME_FERIE
• Si le jour férié tombe un jeudi-vendredi ou samedi alors liste déroulante JE_VE_SA_FERIE

Et ci ce n'est pas un jour férié alors c'est la formule =CHOISIR(JOURSEM(A$1;2);LU;MA;ME;JE_VE_SA;JE_VE_SA;JE_VE_SA;NORMAL)

Merci beaucoup

Re,

On peut utiliser le même genre de formule pour les fériés :

=SI(NB.SI(JFeries!$B$2:$U$11;A$1)>0;CHOISIR(JOURSEM(A$1;2);LU_FERIE;MA_FERIE;ME_FERIE;JE_VE_SA_FERIE;JE_VE_SA_FERIE;JE_VE_SA_FERIE;NORMAL);CHOISIR(JOURSEM(A$1;2);LU;MA;ME;JE_VE_SA;JE_VE_SA;JE_VE_SA;NORMAL))

Mais surtout en définissant vos noms sur l'étendue du classeur et non pas seulement sur la feuille concernée. Il faut supprimer les mauvais et les recréer (MA_FERIE, ME_FERIE, JE_VE_SA_FERIE)

ça fonctionne parfaitement.

Merci