Création onglet et insertion données

Bonjour,

je galère depuis un moment sur un projet.

Nous avons une liste de numéro d'affectation avec des collaborateurs affectés à ses numéros.

je souhaiterais, si possible, créer, à partir de cette liste, un onglet par numéro d'affection et intégrer, à cet onglet, tous les collaborateurs affectés et leurs données.

Bien entendu, les données étant confidentielles, je ne peux vous envoyer le véritable fichier.

Pour information, j'ai 40 colonnes par ligne.

Merci beaucoup pour votre précieuse aide.

Roandjepa

Bonjour roandjepa,

Je te retourne ton fichier Excel modifié :

Ctrl e ➯ travail effectué

Alt F11 pour voir le code VBA, puis revenir sur Excel

Si besoin, tu peux demander une adaptation.

Merci de me dire si ça te convient.

dhany

Bonjour, Salut Dhany !

Une autre méthode... A tester.

Sub RépartOnglets()
    Dim Tbl(), TblT(), PlNum, PlTft, nn%, m%, n%, k%, i%
    With ActiveSheet.Range("A1").CurrentRegion
        n = .Rows.Count
        k = .Columns.Count - 1
        .Sort key1:=.Cells(1, 1), order1:=xlAscending, Header:=xlYes
        PlNum = .Resize(, 1).Value
        PlTft = .Offset(, 1).Resize(, k).Value
    End With
    For i = 2 To UBound(PlNum)
        ReDim Preserve Tbl(1, nn)
        Tbl(0, nn) = PlNum(i, 1)
        ReDim TblT(m)
        TblT(m) = WorksheetFunction.Index(PlTft, 1, 0)
        Do While PlNum(i, 1) = Tbl(0, nn)
            m = m + 1: ReDim Preserve TblT(m)
            TblT(m) = WorksheetFunction.Index(PlTft, i, 0)
            i = i + 1
            If i > UBound(PlNum) Then Exit Do
        Loop
        Tbl(1, nn) = TblT
        nn = nn + 1
        Erase TblT
        i = i - 1: m = 0
    Next i
    Application.ScreenUpdating = False
    For i = 0 To nn - 1
        With Worksheets.Add(after:=Worksheets(Worksheets.Count))
            .Name = Tbl(0, i)
            .Range("A1").Resize(UBound(Tbl(1, i)) + 1, k).Value = WorksheetFunction.Transpose( _
             WorksheetFunction.Transpose(Tbl(1, i)))
        End With
    Next i
End Sub

Cordialement.

merci beaucoup,

les deux solutions correspondent à ce que je recherchais.

mille mercis ..

merci pour ton retour, et pour avoir passé le sujet en résolu !

dhany