Copier valeur cellule dans une colonne à la suite

Bonjour,

J'aimerai connaître une macro pour exécuter ceci :

Voilà je voudrai copier la valeur d'une cellule (admettons C1) d'un fichier Excel (Exemple01) et la copier dans un autre classeur (Exemple02) et que celle-ci soit copier dans la colonne "A" juste après les autres données.

J'avais trouvé ceci mais je n'arrive pas à l'adapter pour l'utiliser entre deux classeurs...

Sub Copie_Source()
Dim rangeDepart As Range
Application.ScreenUpdating = False
    Range("A2").Copy
    Set rangeDepart = Range("A2")
    derniereLigne = 1
    While Len(Trim(rangeDepart.Value)) > 0
    Set rangeDepart = rangeDepart.Offset(1, 0)
    Wend
    rangeDepart.PasteSpecial Paste:=xlValues
Application.ScreenUpdating = True
End Sub

Merci pour votre aide

Bonjour JukeBox, bonjour le forum,

Le code ci-dessous est à placer dans le classeur destination (qui reçoit la copie) et à adapter car tu n'as pas daigner donner beaucoup de renseignements. Lance la macro et si le classeur source n'est pas ouvert, le code l'ouvrira, à condition qu'il se trouve dans le même dossier que le classeur destination...

Sub Copie_Source()
Dim CD As Workbook 'déclare la variable CD (Classeur Destination)
Dim OD As Worksheet 'déclare la variable OD (Onglet Destination)
Dim DEST As Range 'déclare la variable DEST (cellule de DESTination)
Dim CA As String 'déclare la variable CA (Chemin d'Accès)
Dim CS As Workbook 'déclare la variable CS (Classeur Source)
Dim OS As Worksheet 'déclare la variable OD (Onglet Destination)

Set CD = ThisWorkbook 'définit le classeur destination OD
Set OD = CD.Worksheets("Feuil1") 'définit l'onglet destination OD (à adapter à ton cas)
Set DEST = OD.Cells(Application.Rows.Count, "A").End(xlUp).Offset(1, 0) 'définit la cellule de destination DEST (première cellule vide de la colonne A, à adapter à ton cas)
CA = CD.Path & "\" 'définit le chemin d'accès CA
On Error Resume Next 'gestion des erreurs (en cas d'erreur passe à la ligne suivante)
Set CS = Workbooks("Exemple01.xlsx") 'définit la classeur source (à adapter à ton cas), génère une erreur si ce classeur n'est pas ouvert
If Err <> 0 Then 'condition : si une erreur a été générée
    Set CS = Workbooks.Open(CA & "Exemple01.xlsx") 'définit le classeur source en l'ouvrant
End If 'fin de la condition
On Error GoTo 0 'fin de la gestion des erreurs
Set OS = CS.Worksheets("Feuil1") 'définit l'onglet source OS (à adapter à ton cas)
OS.Range("A2").Copy DEST 'copie la cellule A2 (à adapter à ton cas) de l'onglet source et la colle dans DEST
End Sub

Salut ThauThème,

Merci pour ton message et ton code, j'adapterai selon mon usage !

Je testerai ça dans la journée donc je répondrai ici pour dire si cela a fonctionné

Merci encore, c'est super !

Bonjour,

Désolé pour la réponse tardive.. Tout fonctionne correctement

Un grand MERCI à toi ThauThème