Copier les données de 2 feuilles et les coller sur une 3ème

Bonjour à tous,

J'aimerais, à l'aide de VBA, pouvoir copier les données de ma feuille Base ainsi que celles de ma feuille Contrepartie et les mettre l'une en dessous de l'autre dans la feuille import final

Je n'ai pas toujours le même nombre de ligne.

Je dois faire ce copier coller en valeur.

Ensuite, si possible, j'aimerais trier les données de A à Z grâce à ma colonne J

Si tout cela est possible j'aimerais le lancer grâce à un bouton affiché dans la feuille import final

Merci d'avance,

Bonne fin de journée

Nalyd

Bonjour,

Sub IMPORTER()
Dim b As Worksheet, c As Worksheet
    Range("A1").CurrentRegion.Offset(1, 0).Clear
    Set b = Sheets("Base")
    Set c = Sheets("Contrepartie")

    Data = b.Range("A1").CurrentRegion.Offset(1, 0).Value
    Range("A" & Rows.Count).End(xlUp).Offset(1, 0).Resize(UBound(Data), UBound(Data, 2)) = Data

    Data = c.Range("A1").CurrentRegion.Offset(1, 0).Value
    Range("A" & Rows.Count).End(xlUp).Offset(1, 0).Resize(UBound(Data), UBound(Data, 2)) = Data

    derL = Range("A" & Rows.Count).End(xlUp).Row
    ActiveSheet.Sort.SortFields.Clear
    ActiveSheet.Sort.SortFields.Add Key:=Range("J2"), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortTextAsNumbers
    With ActiveSheet.Sort
        .SetRange Range("A2:J" & derL)
        .Header = xlNo
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With

End Sub

Bonjour,

Merci pour votre réponse très rapide,

Cela fonctionne très bien !!

Merci à vous,

Nalyd

Parfait !

Tu peux alors solder le fil de discussion en cliquant sur le V