Consolider des données textes

Bonjour à toutes et à tous,

Je viens chercher de l'aide pour accélérer le traitement de ma macro. J'utilise VBA depuis peu de temps.

Sur un classeur, j'ai 5 onglets avec le même type de tableau, mix mots et chiffres, 70 colonnes et 500 lignes.

La première ligne reprend le titre des colonnes.

Je souhaite consolider ces données avec cette macro qui fonctionne mais qui est relativement longue.

J'ai entendu parler de la possibilité de stocker les données dans une "Table" pour copier toutes les copier d'un coup.

Voici ma macro :

Sub retraiter()

T1 = Timer

Application.ScreenUpdating = False

dligne = Consolidation.Range("A10000").End(xlUp).Row

If dligne > 1 Then Consolidation.Range("A2:Br" & dligne).ClearContents

For i = 1 To 5

Sheets(i).Select

dligne = Sheets(i).Range("A10000").End(xlUp).Row

For j = 2 To dligne

Sheets(i).Select

Rows(j).Copy

Consolidation.Select

LastLigne = Range("A10000").End(xlUp).Row + 1

Cells(LastLigne, 1).Select

ActiveSheet.Paste

Next j

Next i

Consolidation.Select

T2 = Timer

Durée = Round(T2 - T1)

Sheets("Statistiques").Range("A50") = " Durée d'exécution " & Durée & " sec. "

End Sub

Je vous remercie d'avance pour votre aide.

Bien Cordialement.

Bonjour et bienvenue sur le forum

Tu devrais joindre ton fichier...

Bye !

Bonjour,

Une proposition à étudier (sans fichier ).

Cdlt.

Sub retraiter()
Dim ws As Worksheet
Dim dligne As Long, I As Long
Dim T1 As Single, T2 As Single
Dim Durée As String
    T1 = Timer
    Application.ScreenUpdating = False
    consolidation.Cells(1).CurrentRegion.Offset(1).ClearContents
    dligne = 2
    For I = 1 To 5
        Set ws = Sheets(I)
        ws.Cells(1).CurrentRegion.Offset(1).Copy Destination:=consolidation.Cells(dligne, 1)
        dligne = consolidation.Cells(Rows.Count, 1).End(xlUp).Row + 1
    Next I
    T2 = Timer
    Durée = Format(T2 - T1, "0.00")
    MsgBox " Durée d'exécution " & Durée & " sec. "
End Sub

Bonjour,

Je vous remercie pour vos retours.

je mets en pièce jointe mon fichier test.

Merci encore de votre aide.

Bien Cordialement.

Bonjour,

Je te remercie, la macro marche très bien, 0.57sec !!!

je risque de poser quelques questions si je n'arrive pas à tout comprendre.

A bientôt sur le forum.