Condition SI VBA

Bonjour à tous,

j'ai un tableau avec une formule qui me permet lorsque je double clic sur un cellule, une feuil s'ouvre avec la valeur de la cellule précédente. Cette formule fonctions très bien.

En revanche, je souhaiterai lorsque je double clic sur la cellule, lorsque la code article commence par "LSPCC" la feuil 1 s'ouvre et lorsque que le code article commence par "LSPCC E" cela soit la feuil 2 qui s'ouvre.

Est-ce que quelqu'un pourrait me venir en aide?

Voila mon code qui fonctionne pour la 1ere partie:

Private Sub worksheet_BeforeDOubleClick(ByVal Target As Range, Cancel As Boolean)

'Ouvrir une feuil à partir d'un double clic avec renvoie de la valeur, le 21/02/2020 par Guillaume

If Selection.Value = "LSPCC 02" Then

If Not Intersect(Target, Range("B6:B19")) Is Nothing Then

Sheets("controle").Range("H5") = Selection.Value

Sheets("controle").Activate

End If

Else

If Selection.Value = "LSPCC E01" Then

If Not Intersect(Target, Range("B6:B19")) Is Nothing Then

Sheets("controle-ech").Range("H5") = Selection.Value

Sheets("controle-ech").Activate

End If

End If

End If

'Protection de la feuil, le 24/02/2020 par Guillaume

ActiveSheet.Protect DrawingObjects:=True, Contents:=True, Scenarios:=True

End Sub

Bonjour,

Un essai, si j'ai bien saisie la problématique :

Private Sub worksheet_BeforeDOubleClick(ByVal Target As Range, Cancel As Boolean)

If Not Intersect(Target, Range("B6:B19")) Is Nothing Then
    Cancel = True
    If Target.Value Like "LSPCC E*" Then
        Sheets("controle-ech").Range("H5") = Target.Value
        Sheets("controle-ech").Activate
    ElseIf Target.Value Like "LSPCC*" Then
        Sheets("controle").Range("H5") = Target.Value
        Sheets("controle").Activate
    End If
End If

End Sub

PS : sauf erreur de ma part, Selection n'a rien à faire dans cette macro... S'il s'agit bien de la cellule active au moment d'éxécuter la macro, elle s'appelle Target.

Super merci beaucoup Pedro22 ça fonctionne