Compter le nombre de population Rouge

Bonjour,

Demande d'aide pour Compter le nombre d'individu rouge dans une colonne.

Je ne sais pas si cela est possible avec excel, j'ai la formule global que j'ai mis dans le fichier Joint pour compter la totalité

mais pas pour différencier les couleurs

Merci d'avance

Bonsoir le forum,

=NBCAR(B2)-NBCAR(SUBSTITUE(B2;",";""))+NBCAR(B4)-NBCAR(SUBSTITUE(B4;",";""))+2

mbbp bonsoir et Merci

ta formule est figé pour l'exemple que j'ai fourni, mais non fonctionnel dés lors que les populations rouge changeront

de ligne.

dés fois j'ai beaucoup de lignes rouge par forcément les memes donc il faudrait vraiment une reconnaissance

de couleur pour les dénombrer.

Peut être infaisable ?

Cordialement

Bonsoir,

Fonction personnalisée :

Function NBELEMROUGE(Plg As Range, sépar As String)
    Dim n%, c As Range
    For Each c In Plg
        If c <> "" Then
            If c.Font.Color = vbRed Then _
             n = n + UBound(Split(c, sépar)) + 1
        End If
    Next c
    NBELEMROUGE = n
End Function

=NBELEMROUGE(B2:B6;",")

te renverra 11.

Cordialement.

Bonsoir tout le monde,

Ci dessous, une version différente sans fonction, mais par vba.

Cellule A1 permet de prendre la couleur rouge de l'écriture.

à voir si cela vous convient...

le code :

Sub recherche_ecriture_rouge()
    Dim Chn As String
    Dim lesval() As String
    Dim NbRouge As Long
    Dim Nblect As Long
    Dim k As Long
    Dim n As Long
    Dim li As Long
    Dim couleur As Long
    Dim compte As Boolean
    Dim nbPopTotal As Long
    Dim nbPopNormal As Long
    Dim nbPopRouge As Long
    Dim ecrnoir As Long
    Dim ecrrouge As Long
    Dim totalecr As Long
    With Sheets(1)
        couleur = .Cells(1, 1).Font.Color
        n = .Cells(Rows.Count, 2).End(xlUp).Row
        For li = 2 To n
            compte = False
            Nblect = Nblect + 1
            If .Cells(li, 2).Font.Color = couleur Then NbRouge = NbRouge + 1: compte = True
            Chn = .Cells(li, 2)
            lesval = Split(Chn, ",")
            For k = 0 To UBound(lesval)
                totalecr = totalecr + 1
                nbPopTotal = nbPopTotal + Val(lesval(k))
                If compte Then
                        ecrrouge = ecrrouge + 1
                        nbPopRouge = nbPopRouge + Val(lesval(k))
                    Else
                        ecrnoir = ecrnoir + 1
                        nbPopNormal = nbPopNormal + Val(lesval(k))
                End If
            Next k
        Next li
        .Cells(4, 5) = "Nombre cellule non-vide : " & Nblect
        .Cells(5, 5) = "Nombre cellule rouge : " & NbRouge
        .Cells(6, 5) = "total de nombre : " & totalecr
        .Cells(7, 5) = "total de nombre non-rouge : " & ecrnoir
        .Cells(8, 5) = "total de nombre rouge : " & ecrrouge
        .Cells(9, 5) = "calcul population totale : " & nbPopTotal
        .Cells(10, 5) = "calcul population rouge : " & nbPopRouge
        .Cells(11, 5) = "calcul population non-rouge : " & nbPopNormal
    End With
End Sub

MFerrand, très belle fonction personnalisée...

Merci Thihii ! Mais je ne réponds qu'à la demande exprimée ! Toi, tu devances les demandes non encore exprimées...

Attendons la suite ! A+

MFerrand et thihii Merci pour votre efficacité le résultat escompté est atteint

Vos deux codes sont l'un comme l'autre à la pointe.

Thihii Merci pour cette belle prestation qui servira à comprendre les possibilités qu'offrent ce genre de requête sur le forum.

pour ma part je garderai le ratio Rouge/PopTotal

Merci infiniment a vous deux et Bravo

Cordialement

Bonsoir tout le monde,

MFerrand a écrit :

Merci Thihii ! Mais je ne réponds qu'à la demande exprimée ! Toi, tu devances les demandes non encore exprimées...

Attendons la suite ! A+

Dans une demande, l'on aperçoit presque la suivante...

Tout en donnant plus que la demande, du moins l'idée qui me passe en tête, non seulement je me fais plaisir, et j'espère que cela 'peut servir'... C'est le partage.

Mais ne pas hésiter à me reprendre, si des erreurs se hissent dans mes idées, j'apprends tout autant qu'un débutant. Le vba est tellement vaste et riche, que je suis loin d'en connaitre un quart... ou peut-être moins !