Colorier la ligne où se trouve le choix d'un combobox

Bonjour,

Je dois colorier en jaune la ligne entière en fonction du choix d'un combobox.

En colonne A j'ai des noms, grâce a un userform et un combobox j'en choisi un plus une réponse au choix (1, 2 ou 3) et en fonction de la réponse la ligne du combobox se colorie d'une certaine couleurs.

Avez vous une idée ? Merci

Bonjour Pagesalex, bonjour le forum,

Manque de précision pour pouvoir te donner une réponse !...

• Le choix se fait via quoi : Optionbutton, ComboBox, autre ?

• Comment est alimenté la ComboBox des noms ?

• Les noms en colonne A contiennent-ils des doublons.

Pour éviter de perdre du temps, un fichier exemple serait le bienvenu...

Je joins un fichier test

Il n'y a pas de doublons, le choix se fait avec des optionsbutton

Re,

En pièce jointe ton fichier modifié avec le code commenté...

C'est parfait merci !

Petite question : comment changer les couleurs ?

Re,

à adapter :

Private Sub CommandButton1_Click()
Dim LI As Integer 'déclare la variable LI (LIgne)
Dim COL As XlColorIndex 'déclare la variable COL (COULEUR)
Dim CTRL As Control 'déclare la variable CTRL (ConTRôLe)

If Me.ComboBox1.ListIndex = -1 Then 'condition : si le choix n'appartient a la liste
    MsgBox "Vous devez choisir un adhérent !" 'message
    Me.ComboBox1.SetFocus 'place le curseur dans la ComboBox1
    Exit Sub 'sort de la procédure
Else 'sinon
    LI = Me.ComboBox1.Column(0, Me.ComboBox1.ListIndex) 'récupère la ligne dans la variable LI
End If 'fin de la condition
For Each CTRL In Me.Controls 'boucle sur tous les contrôles CTRL de l'UserForm
    If TypeOf CTRL Is MSForms.OptionButton Then 'condition : si le contrôle est un bouton d'option
        If CTRL.Value = True Then GoTo suite 'si le bouton est coché, va à l'étiquette "suite"
    End If 'fin de la condition
Next CTRL 'prochain contrôle de la boucle
MsgBox "Vous devez choisir la relance !" 'message
Exit Sub 'sort de la procédure
suite: 'étiquette
Select Case CTRL.Caption 'agit en fontion du texte du bouton d'Option
    Case "Pas de réponses" 'cas
        COL = 3 'couleur rouge (essaie de 1 à 56 pour trouver la couleur qui te plaît)
    Case "Non" 'cas
        COL = 4 'couleur verte (essaie de 1 à 56 pour trouver la couleur qui te plaît)
    Case "Oui" 'cas
        COL = 6 'couleur jaune (essaie de 1 à 56 pour trouver la couleur qui te plaît)
End Select 'fin de l'action en fonction du texte du bouton d'Option
Cells(LI, 1).Resize(1, 26).Interior.ColorIndex = COL 'colore la ligne LI avec la couleur COL
End Sub

Merci beaucoup !