Bonjour,
La méthode Find est ton amie...
Exemple (commenté) :
Option Explicit
Sub Cherche()
'déclaration des variables :
Dim Trouve As Range, PlageDeRecherche As Range
Dim Valeur_Cherchee As String, AdresseTrouvee As String
'********* à adapter ***********
'affectation de valeurs aux variables :
'on va chercher le mot "pomme" situé en Feuil2 Cellule B6
Valeur_Cherchee = Sheets("Feuil2").Range("B6").Value
'dans la troisième colonne de la feuille Feuil1
Set PlageDeRecherche = Sheets("Feuil1").Columns(3)
'*******************************
'méthode find, ici on cherche la valeur exacte (LookAt:=xlWhole)
Set Trouve = PlageDeRecherche.Cells.Find(what:=Valeur_Cherchee, LookAt:=xlWhole)
'traitement de l'erreur possible : Si on ne trouve rien :
If Trouve Is Nothing Then
'ici, traitement pour le cas où la valeur n'est pas trouvée
AdresseTrouvee = Valeur_Cherchee & " n'est pas présent dans " & PlageDeRecherche.Address
Else
'ici, traitement pour le cas où la valeur est trouvée
AdresseTrouvee = Trouve.Address
'Pour la ligne utiliser la syntaxe suivante :
'AdresseTrouvee = Trouve.Row
End If
MsgBox AdresseTrouvee
'vidage des variables
Set PlageDeRecherche = Nothing
Set Trouve = Nothing
End Sub
https://www.commentcamarche.net/faq/36886-fonction-find-dans-vba-recherche-de-donnees-sous-excel