Code VBA pour graphique

Bonjour,

Dans chacune de mes feuilles

J'ai une série temporelle de la cellule G20 à AV20 que je veux mettre en abscisse

Une série de valeur de la cellule G22 à AV22 que je veux mettre en ordonné

Un nom en C22 que je veux mettre en titre

Quel est le code VBA pour tracer la courbe (j'utilise la macro et le graphique se construit dans la feuille où je suis)

merci d'avance pour votre aide.

up

Bonjour,

Merci de joindre un fichier.

Cdlt.

Voici un exemple, je veux pouvoir tracer la courbe en activant une macro, pour cette feuille mais pour n'importe laquelle.

merci de votre aide.

Bonsoir,

Un début de réponse à étudier.

Ctrl + Maj + w pour lancer la procédure dans la feuille active.

Cdlt.

Option Explicit

Public Sub CreateChart()
' CTRL + MAJ + w pour lancer la procédure
Dim ws As Worksheet
Const X_range As String = "$G$20:$AV20"
Const Y_range As String = "$G$22:$AV$22"
Dim ACell As Range, rngChart As Range
Dim objChart As ChartObject

    Application.ScreenUpdating = False

    Set ws = ActiveSheet

    On Error Resume Next
    ws.ChartObjects(1).Delete
    On Error GoTo 0

    With ws
        Set ACell = .Cells(2, 2)
        Set objChart = .ChartObjects.Add _
                       (Left:=ACell.Left, _
                        Top:=ACell.Top, _
                        Width:=500, _
                        Height:=250)
        With objChart.Chart
            .ChartType = xlLine
            .SeriesCollection.NewSeries
            .SeriesCollection(1).XValues = ws.Range(X_range)
            .SeriesCollection(1).Values = ws.Range(Y_range)
            .HasTitle = True
            .ChartTitle.Characters.Text = ws.Cells(22, 3)
            .HasLegend = False
        End With
    End With

    Set objChart = Nothing
    Set rngChart = Nothing: Set ACell = Nothing
    Set ws = Nothing

End Sub