Cocher un champs case à cocher d'un formulaire PDF à partir de VBA

Bonjour, je lisais avec intérêt ce forum sans m'y être enregistré, c'est maintenant fait.

J'ai lu plusieurs discussion sur le sujet mais je ne n'ai pas réussi à résoudre mon problème

j'ai récuépér un formulaire pdf que de dois alimenter grace à vba à partir de données de ma feuille excel.

j'utilise le code suivant que j'ai récupéré du forum et adapté dont j'avoue ne pas tout trop comprendre mais je parviens à alimenter les champs texte et numérique par contre dans le code ci-dessous je ne réussi pas à cocher le dernier champs "case à cocher", j'ai essayé de mettre comme valeur OUI, TRUE etc ... en vain, le code ne plante pas, se déroule normalement, mais la case n'est pas cochée.

Merci de votre aide.

Christian

Sub Ecriture_ChampsFormulaire()

Dim AVDoc As Object

Dim PDDoc As Object

Dim JSO As Object

Dim x As Object

Dim sChemin As String

Dim cefichier As String

Dim wnom_client1 As String

Dim wnom_client2 As String

Dim wnom_locataire As String

cefichier = ThisWorkbook.Name

Set AVDoc = CreateObject("AcroExch.AVDoc")

sChemin = ThisWorkbook.Path & "\" & "Contrat LOA VOITURE.PDF"

If AVDoc.Open(sChemin, "") Then

Set PDDoc = AVDoc.GetPDDoc

Set JSO = PDDoc.GetJSObject

wnom_client1 = Workbooks(cefichier).Worksheets("Fiche renseignements").Range("Prénom1") & " " & _

Workbooks(cefichier).Worksheets("Fiche renseignements").Range("nom_client1")

wnom_locataire = wnom_client1

If Workbooks(cefichier).Worksheets("Fiche renseignements").Range("nom_client2") <> "" Then

wnom_client2 = Workbooks(cefichier).Worksheets("Fiche renseignements").Range("Prénom2") & " " & _

Workbooks(cefichier).Worksheets("Fiche renseignements").Range("nom_client2")

wnom_locataire = wnom_locataire & " / " & wnom_client2

End If

Set x = JSO.getField("locataire-client")

x.Value = wnom_locataire

Set x = JSO.getField("locataire-telephone")

x.Value = "Essai Adresse"

Set x = JSO.getField("locataire-nom-prenom")

x.Value = wnom_client1

Set x = JSO.getField("locataire-adresse")

x.Value = "près de chez moi"

Set x = JSO.getField("locataire-cp")

x.Value = "75000"

Set x = JSO.getField("locataire-commune")

x.Value = "test commune"

' CheckBox cochée qui ne fonctionne pas

Set x = JSO.getField("celib")

x.Value = "Oui"

PDDoc.Save 1, ThisWorkbook.Path & "\" & "Essai.pdf"

PDDoc.Close

Set x = Nothing

Set JSO = Nothing

Set PDDoc = Nothing

End If

Set AVDoc = Nothing

KillAcrobat

End Sub

Private Sub KillAcrobat()

Dim Rep As Variant

Rep = Shell("Taskkill /im Acrobat.exe /f", 0)

End Sub

j 'ai trouvé il faut que dans propriété du champs dans le formulaire PDF, la valeur d'exportation soit positionée à "Oui" et pas avec le nom du champs.