Classer les feuilles Excel

Bonjour,

je souhaite classer les feuilles excel par ordre alphabétique, sauf la feuille "récapitulatif" que j'aimerai garder à la fin de toutes les feuilles mais impossible de trouver une formule.

Merci par avance pour votre aide

tableau en PJ

Bien cordialement

Mango19

Bonjour,

Ça ne peut pas se faire par formule, il faut impérativement passer par une macro VBA.

Par exemple :

Option Explicit
Sub Classement_Feuilles()
' Classement aphanumérique des feuilles
' 12/05/16  Patrice33740  V1-2-00
Dim shA As Object                 'Feuille active (worksheet ou chart)
Dim n°Src As Integer              'N° d'index de la feuille source
Dim n°Dst As Integer              'N° d'index de la feuille destination
Dim MàjEcran As Boolean           'État du ScreenUpdating
Const nomRécap As String = "récapitulatif"

  ' Mémoriser le contexte
  MàjEcran = Application.ScreenUpdating
  Set shA = ActiveSheet
  ' Désactiver la mise à jour écran
  Application.ScreenUpdating = False
  ' Trier les feuilles
  n°Dst = 1
  Do
    If n°Dst > Sheets.Count - 1 Then Exit Do
    n°Src = n°Dst + 1
    Do
      If n°Src > Sheets.Count Then Exit Do
        If UCase(Sheets(n°Dst).Name) > UCase(Sheets(n°Src).Name) Then
          Sheets(n°Src).Move before:=Sheets(n°Dst)
        End If
      n°Src = n°Src + 1
    Loop
    n°Dst = n°Dst + 1
  Loop
  ' Placer la feuille récap en dernière position
  Sheets(nomRécap).Move after:=Sheets(Sheets.Count)
  ' Rétablir le contexte
  shA.Activate
  Application.ScreenUpdating = MàjEcran

End Sub

Bonjour,

merci pour votre réponse rapide je viens d'essayer et l'erreur suivante se produit : indice n'appartient pas à la sélection

je suis une novice en excel pouvez vous m'aider à résoudre cette erreur

Cordialement

Mango19

Bonjour,

Très probablement du fait que le véritable nom de la feuille récapitulatif n'est pas "récapitulatif",

Il faut indiquer le nom exact (en tenant compte de la casse) sur la ligne :

Const nomRécap As String = "récapitulatif"