Chercher une valeur dans un tableau
Bonjour,
existe t il une fonction qui rassemble rechercheV et rechercheH. J'utilise habituellement ces 2 fonctions disctinctement mais la je voudrais les combiner, c'est à dire que la valeur que je recherche sur une plage doit me renvoyer le résultat de la 12eme colonne et de la 3eme ligne à partir de ma valeur trouvée.
J'espère être clair.
Merci d'avance pour votre aide.
Bonjour,
Tu as la fonction INDEX associée à un double EQUIV :
=INDEX(Tableau;EQUIV(n°_ligne;lignes;0);EQUIV(n°_colonne;colonnes;0)Je te laisse tenter d'adapter à ton vrai fichier.
Si problème adaptation, reviens avec un extrait de ton fichier (anonymisé).
@+
dans mon tableau ci joint, je cherche à retrouver en automatique dans C7 la valeur L13 en D7 la valeur M13 et en C8 la valeur L14 et en D8 la valeur M14 et ainsi de suite, tout cela à partir du critère de recherche en A7 puis A10 etc.
re,
En C7, cette formule :
=INDEX($L$7:$M$10;EQUIV($B7;$K$7:$K$10;0);EQUIV(C$6;$L$6:$M$6;0))à recopier une fois à droite, puis sur les lignes concernées
Je te laisse tester
@+
merci de la réponse, je vais essayer et tenir informé.
-- Mar Avr 13, 2010 2:00 pm --
ça à l'air de fonctionner, il faut que je fasse évoluer l'argument de la fonction EQUIV de 0 à 1 etc.
Merci, une bien belle épine du pied enlevée.
Bon, en fait cela ne fonctionne pas car l'argument de la fonction EQUIV : -1, 0, +1 à priori ne me renvoie la valeur la plus petite, plus grande ou plus proche. Ce que je veux, c'est aller chercher la valeur de la 2eme colonne et de la premier ligne puis 2eme ligne puis 3eme ligne etc pour chaque valeur recherchée.
ex
article qté
ABC 10
ABC 18
ABC 2
CDE 1
CDE 50
Je veux dans un tableau aller chercher la valeur "qté" pour chaque ligne de l'article ABC.
Bonsoir,
Un fichier plus proche de ton vrai fichier nous permettrait de t'apporter une aide plus précise.
Sur la base de ton dernier fichier, je te propose ceci :
en B7 :
=K7en C7, une formule matricielle :
=INDEX($L$7:$L$13;EQUIV($B7+LIGNE()/10^10;$K$7:$K$13+LIGNE($K$7:$K$13)/10^10;0))Formule matricielle à valider par CTRL + MAJ + ENTREE
en D7, une autre formule matricielle (sa petite soeur) :
=INDEX($M$7:$M$13;EQUIV($B7+LIGNE()/10^10;$K$7:$K$13+LIGNE($K$7:$K$13)/10^10;0))Formule également matricielle donc à valider aussi par CTRL + MAJ + ENTREE
Formules à recopier vers le bas
On peut ajouter un test pour les 0 ou appliquer un format personnalisé ou bien encore une mise en forme conditionnelle.
Je te laisse tester
@+
Bonjour,
j'ai recopié, ça me met #valeur et #NA et comme je ne comprends pas bien la formule ca devient compliqué.
LIGNE()/10^10 ==> ça veut dire quoi ?
je vais faire un fichier similaire à celui sur lequel je travaille et je le joindrai.
-- Jeu Avr 15, 2010 11:38 am --
je joint un fichier avec des explications, j'espère être suffisamment clair !!!
Bonjour,
Essaye avec cette formule matricielle en B6 :
=SI(INDEX($I$1:$I$25;PETITE.VALEUR(SI($H$6:$H$25=$A6;($H$6:$H$25=$A6)*LIGNE($H$6:$H$25));NB.SI($A$6:$A6;$A6)))=0;"";INDEX($I$1:$I$25;PETITE.VALEUR(SI($H$6:$H$25=$A6;($H$6:$H$25=$A6)*LIGNE($H$6:$H$25));NB.SI($A$6:$A6;$A6))))Formule matricielle à valider par CTRL + MAJ + ENTREE
Sa petite soeur en C6 :
=SI(INDEX($J$1:$J$25;PETITE.VALEUR(SI($H$6:$H$25=$A6;($H$6:$H$25=$A6)*LIGNE($H$6:$H$25));NB.SI($A$6:$A6;$A6)))=0;"";INDEX($J$1:$J$25;PETITE.VALEUR(SI($H$6:$H$25=$A6;($H$6:$H$25=$A6)*LIGNE($H$6:$H$25));NB.SI($A$6:$A6;$A6))))Egalement matricielle donc à valider par CTRL + MAJ + ENTREE
Pour cette 2ème formule, mettre au format Date
à recopier ensuite vers le bas
@+