Changer d'onglet par double clic (conditions inside)

Bonjour à tous,

je vous fait part de mon problème car tout seul dans mon coin je sèche !!!

Voici comment est agencé mon classeur :

5 onglets : Feuil1, sudest, sudouest, nordest et nordouest.

Sur Feuil1 j'ai un tableau de 2 colonnes. La première correspond à des noms de personne et la deuxième leur secteur respectif.

J'ai créé une liste de choix déroulante qui en fonction du salarié choisi me retourne dans une autre cellule son secteur (SE,SO,NE ou NO).

Je souhaiterai donc, qu'en fonction du résultat retourné dans la cellule on puisse double cliquer dessus et arriver à l'onglet respectif.

EX : je choisi durand dans la liste, le secteur SO s'affiche dans la cellule en face. Je double clique dessus et j'arrive dans l'onglet sudouest. Pareil avec alex ... je doubleclique sur SE et j'arrive sur l'onglet sudest, ect...

J'ai commencé par regarder vers le code VBA "BeforeDoubleClick" et après moult tâtonnements j'ai bien réussi à entrevoir de la lumière, mais le tunnel est très long et ces fichues conditions (If, ElseIf ???) me barrent la route :p

Bref, je sollicite votre aide

Je vous mets en pj mon fichier.

Par avance merci pour tout.

(en espérant avoir été clair dans ma demande)

alex

Bonjour

Une solution (ne doit pas être la seule)

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
  If Target.Address <> "$E$3" Then Exit Sub
  Cancel = True
  Select Case Target
    Case "SE"
      Sheets("sudest").Select
    Case "SO"
      Sheets("sudouest").Select
    Case "NE"
      Sheets("nordest").Select
    Case "NO"
      Sheets("nordouest").Select
  End Select
End Sub

oO ... c'est du rapide

merci beaucoup, je viens de tester et ça fonctionne très bien.

bonsoir c'est encore moi ^^

Dernière petite question :

Dans la partie de code suivante : If Target.Address <> "$E$3" Then Exit Sub

$E$3 fait référence à une cellule que j'ai nommé secteur via le gestionnaire de noms.

Cependant quand je remplace "$E$3" par secteur le double clic ne fonctionne plus.

J'ai essayé : [secteur] , secteur, "secteur" mais ça ne change rien à mon problème.

Pour quelle raison, le fait d'appeler la cellule par son nom (et non pas pas sur n°de cellule) n'a plus d'effet sur le double clic ? Mauvaise syntaxe ?

Bonsoir

Essayes cela

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
  If Not Intersect([Secteur], Target) Is Nothing Then
    Cancel = True
    Select Case Target
      Case "SE"
        Sheets("sudest").Select
      Case "SO"
        Sheets("sudouest").Select
      Case "NE"
        Sheets("nordest").Select
      Case "NO"
        Sheets("nordouest").Select
    End Select
  End If
End Sub

Merci à toi ça fonctionne à merveille !!!