Calculer l'âge moyen à partir d'une date
Bonjour à tous,
Bref, j'aimerais calculer l'âge moyen à partir de la date de naissance (il y a plusieurs dates, bien entendu), mais selon 2 critères différents.
Voici la formule que j'utilise et qui fonctionne pour ce que je veux faire en grande partie :
=ARRONDI(FRACTION.ANNEE(MOYENNE(Témoin!F4:F124);AUJOURDHUI());2)
Mais, je dois à un moment prendre en compte des critères spécifiques :
J'aimerais que ça me calcule l'age moyen selon qu'il y ait un "C" ou un "N" dans la colonne N - en excluant ceux où il écrit "R" dans la colonne N.
De même, j'aimerais calculer l'âge moyen selon qu'il y ait un "R" à l'exclusion du "C" et du "N".
Voilà où j'en suis :
Si j'applique ma formule précédente (sans distinction de critères, sachant que je ne suis pas encore dans un cas de figure où le critère R soit apparu) :
=ARRONDI(FRACTION.ANNEE(MOYENNE(Témoin!F4:F124);AUJOURDHUI());2)
Mon résultat est 20.65 (ce qui est juste).
Mais si j'inclus une condition, telle :
=ARRONDI(FRACTION.ANNEE(MOYENNE(SI(Témoin!N4:N124="C";Témoin!F4:F124));AUJOURDHUI());2)
Je me retrouve avec un résultat de 110.87 ( ce qui complètement incohérent).
Je ne trouve pas le moyen de lier les deux colonnes réellement...
Merci de vos lumières (en espérant avoir été clair ^^).
PS : je vais essayer de vs refaire un tableau d'exemple, avec des données factices.
-- 12 Nov 2010, 16:09 --
Voici un exemple de mon tableau (simplifié)
Bonjour
Je n'ai pas regardé ton fichier, mais, je suis parti de la question de départ:
Remplace dans ta formule
MOYENNE(Témoin!F4:F124)
par
SOMMEPROD((Témoin!$F$4:$F$124)*(Témoin!$N$4:$N$124="C"))/NB.SI(Témoin!$N$4:$N$124;"C")
pour avoir les C et la même chose avec N
SOMMEPROD((Témoin!$F$4:$F$124)*(Témoin!$N$4:$N$124="N"))/NB.SI(Témoin!$N$4:$N$124;"N")
et pour avoir les C et N en même temps
Pour le Cumul des C et N
=ARRONDI(FRACTION.ANNEE(SOMMEPROD((Témoin!$F$4:$F$124)*(Témoin!$N$4:$N$124={"C"."N"}))/SOMMEPROD(N(Témoin!$N$4:$N$124={"C"."N"}));AUJOURDHUI());2)
Cordialement
Merci.
Et si je veux les deux résultats en un seul , j'écris :
(SOMMEPROD((Témoin!$F$4:$F$124)*(Témoin!$N$4:$N$124="C"))/NB.SI(Témoin!$N$4:$N$124;"C") + SOMMEPROD((Témoin!$F$4:$F$124)*(Témoin!$N$4:$N$124="N"))/NB.SI(Témoin!$N$4:$N$124;"N"))/2
?
Mais à première vue, j'ai pas le même résultat qu'avec la toute première formule : 20.94 au lieu de 20.65
Edit:
Oups. J'avais pas vu la fin de ton message...
Je viens de tester ta formule, ça me marque #DIV/0 comme résultat.
Re Edit :
je suis très bête. J'ai mal copier la fonction (entendre, adapter au tableau). J'ai les mêmes valeurs maintenant : 20.65.
Par contre, si c'est pas trop demander,
SOMMEPROD(N(Exclusion!$N$4:$N$124={"C"."N"})
je ne comprends pas le N avant exclusion. Il signifie quoi?
En tous cas, merci beaucoup.
Bonsoir
Si tu écris
=SOMMEPROD((Témoin!$N$4:$N$124={"C"."N"}))
Le résultat est 0 car cette formule renvoie une matrice de VRAI ou FAUX selon que chaque cellule contient C ou N et une succession de VRAI;VRAI;FAUX;VRAI renvoie 0
Ainsi
=SOMMEPROD(({VRAI.FAUX.VRAI})) renvoie 0
pour compter le nombre de VRAI, il faut transformer la matrice de valeurs boléennes VRAI FAUX en matrice numérique de 1 et 0
ainsi
=SOMMEPROD(N({VRAI.FAUX.VRAI})) renvoie 2
Ces arguments peuvent être utilisés, comme plein d'autres N, --,*1,/1,+0
=SOMMEPROD(N(Témoin!$N$4:$N$124={"C"."N"}))
=SOMMEPROD(--(Témoin!$N$4:$N$124={"C"."N"}))
=SOMMEPROD(1*(Témoin!$N$4:$N$124={"C"."N"}))
Cordialement
Merci beaucoup pour ces éclaircissements.