Calcul plage horaire et jours fériés
Bonjour,
J'ai regardé sur les questions du forum, mais je n'arrive pas à faire ce calcul.
Je dois calculer un temps de travail sur une plage horaire de 8H30 à 19H30 , du lundi au vendredi.
J'ai essayé ce code mais j'ai une erreur #Nom?
=(NB.JOURS.OUVRES(A3;B3)-2)*(hfin-hdeb)+(MOD(B3;1)-hdeb)+(hfin-MOD(A3;1)Merci.
Bonjour,
plusieurs remarques :
(NB.JOURS.OUVRES(A3;B3)-2) pourquoi le -2 ? ( nb.jours.ouvres enlève déjà le week-end)
ensuite (hfin-hdeb) ne correspond à rien d'où le #Nom.
Et si j'ai bien compris le résultat doit te retourner le nombre d'heure travaillé ?
Bonjour @Benoit0846,
Et si j'ai bien compris le résultat doit te retourner le nombre d'heure travaillé ?
Oui tu as tout compris.
Pour ce qui est du code je l'ai pris sur une question du forum. Je suis incapable de te dire.
Merci pour ton aide.
Bonjour à toutes et tous, writer77, Benoit0846,
@writer77,
A tester, j'ai mis les résultats dans la colonne "F"
Cordialement.
Du coup la formule est bonne tu remplace juste hdeb par ta cellule C1 et hfin par D1
Ensuite tu mets un format de cellule standard au lieu de personnalisé.
tu auras le nb de jours de travail, pour l'avoir en heure tu multiplie par 24.
=((NB.JOURS.OUVRES(A3;B3)-2)*($D$1-$C$1)+(MOD(B3;1)-$C$1)+($D$1-MOD(A3;1)))*24
Si grâce à ton code j'obtiens la place, grâce à toi je sortirai du chômage, en faisant une reconversion . A 58 ans j'ai de l'espoir !!!
Merci pour tout.
Re @writer77,
Je revois ma copie, exemple pour "A3, B3"
En somme une journée de travail dure de 8h30 à 19h30 soit 11h00
Donc le vendredi 15/01/2021 16:39:40 jusqu'à 19h30 = 02:50:20
Le 16 et le 17 sont week-end donc 0:00:00
Les 18, 19, 20, 21 sont des journées entières donc 11h00 * 4 jours soit 44:00:00
Le dernier jour 22 est une fin de journée de 8:30:00 à 18:13:03 soit 09:43:03
Si on totalise cela fait ► 02:50:20 + 44:00:00 + 09:43:03 = 56:33:23
Pour finir regarde dans le "Gestionnaire de noms" pour voir les cellules nommées "Hdéb, Hfin, Hjour"
Bon courage pour ta reconversion.
Cdlt
Bonjour@Mdo100,
Je regarde tout ça demain, ce soir la vieillesse se faisant, je suis un peu HS.
Merci très sincèrement pour tout.
Bonjour@Mdo100,
Je viens de comprendre pour le SI et Et.
Et je viens d'apprendre comment faire pour rappeler une ligne dans gestionnaire de noms.
Tous ça grâce à ton code.
Merci.
Maintenant est-il possible de mettre le chiffre 1 en face de chaque cellule qui sont inférieure pour égal à 8H?
j'ai mis cette ligne de code
SI(ET(A3<>"";B3<>"")*ET(F3<=8);1;0)Je ne sais pas pourquoi Excel a voulu mettre une * devant le deuxième ET.
Mais mon code est faux.
En fait je voulais faire
SI A3<>"" ou B3<> "" donc calculer SI F3 <= à 08::00::00 Alors mettre 1 , sinon mettre O
Merci encore pour tout.
Bonjour @writer77,
08:00:00 est égal à 0,333333333333333 centième d'heure.
Donc
=SI(ET(A3<>"";B3<>"";F3<=0,333333333333333);1;0)Cdlt.
Re,
Plus simplement:
=SI(ET(A3<>"";B3<>"";F3*24<=8);1;0)Cdlt
J'ai testé les deux codes.
=SI(ET(A3<>"";B3<>"";F3*24<=8);1;0)
=SI(ET(A3<>"";B3<>"";F3<=0,333333333333333);1;0)Et cela me retourne 00:00:00 dans toutes les cases.
Désolé.
Merci.
Re,
Il faut mettre ta colonne "G" au format "Standard"
Cdlt
Re,
Il faut mettre ta colonne "G" au format "Standard"Effectivement
Merci.
Bonjour,
En retard ?
=(NB.JOURS.OUVRES(A3;B3)-1)*(Hfin-Hdéb)
+SI(NB.JOURS.OUVRES(B3;B3);MEDIANE(MOD(B3;1);Hfin;Hdéb);Hfin)
-MEDIANE(NB.JOURS.OUVRES(A3;A3)*MOD(A3;1);Hfin;Hdéb)Bonjour,
@Jean-Eric, effectivement je n'ais pas pris en compte que le premier où le dernier jour pouvais être un samedi où un dimanche.
Du coup je corrigerais ma formule ainsi.
=SI(ET(A3<>"";B3<>"");SI(NB.JOURS.OUVRES(A3;A3);MOD(Hfin-A3;1);0)+
Hjour*(NB.JOURS.OUVRES(A3;B3)-2)+
SI(NB.JOURS.OUVRES(B3;B3);MOD(B3-Hdéb;1);0);0)Je ne veux pas me prendre le bec avec toi, mais avec ta formule en ligne 17 nous avons une différence.
Toi 1:09:56
Moi 1:28:05
Il y a d'autres lignes ou nous avons des différences.
Sans doute auras-tu une réponse à me faire pour m'expliquer pourquoi ta formule serait juste.
Cdlt
Re @Jean-Eric,
Ça y est j'ai trouvé pourquoi nous avions une différence
@writer77,
Prend la formule de @Jean-Eric, elle donne le bon résultat.
=SI(ET(A3<>"";B3<>"");(NB.JOURS.OUVRES(A3;B3)-1)*(Hfin-Hdéb)
+SI(NB.JOURS.OUVRES(B3;B3);MEDIANE(MOD(B3;1);Hfin;Hdéb);Hfin)
-MEDIANE(NB.JOURS.OUVRES(A3;A3)*MOD(A3;1);Hfin;Hdéb);0)Cdlt.
@mdo100, @Jean-Eric,@Benoit0846,
Franchement vous êtes des pros, et surtout des humanistes.
Un grand et sincère respect et remerciement pour votre aide et partage.