Automatiser un copier/coller

Le 07/12/2017 à 18:06

bonjour à toutes et tous,

voila j'ai un fichier avec 12 onglets (mois) et 18 colonnes par mois

en B =services

en C=documents etc....

dans l'onglet Récup données je récupère les données dans des tableaux (17 au total) sauf que ça en fait des clics car

les tableaux sont sur 12 colonnes (mois) sur 72 lignes (représentant les différents services de l’hôpital).

Dans le tableau (documents):

j'utilise comme formule : =SOMMEPROD((Janvier!$B$3:$B$250="D-G")*(Janvier!$C$3:$C$250)) jusque décembre

en ligne 2: =SOMMEPROD((Janvier!$B$3:$B$250="B-D-M")*(Janvier!$C$3:$C$250)) '''''''''''''''

sauf qu'a chaque tableau je dois modifier le cellule de recherche

dans le tableau imprimés :

=SOMMEPROD((Janvier!$B$3:$B$250="D-G")*(Janvier!$D$3:$D$250))

il n'y a que le critère de la colonne qui change , j'ai déjà réalisée 5 tableaux reste 12 alors je me disais que peut être ou pas il y a une méthode pour gagner du temps .

je joins mon fichier qui sera beaucoup plus explicite

merci a vous

12fichier-excel-dotation-hors-commande-reprographie-eric.xlsm (398.71 Ko)

Le 07/12/2017 à 18:15

Bonjour,

Déjà pour commencer si tu essayer plutôt que de rentrer manuellement à chaque fois dans ta formule SOMMEPROD la valeur D-G ; B-D-M et autres tu mettais = $A2 ; $A3 ; ... et tu aurais juste à décembre jusqu'en bas

A+

Le 07/12/2017 à 18:31

merci Koko_Swiff,

mais se n'est pas trop sur la première partis de la formule qui me gène car celle-ci est récurrente , je la copie/colle dans chaque tableau c'est la deuxième partie qui change de critère de sélection des données.

SOMMEPROD((Janvier!$B$3:$B$250="D-G")*(Janvier!$C$3:$C$250)) à

=SOMMEPROD((Decembre!$B$3:$B$250="D-G")*(Decembre!$C$3:$C$250))

dans l'autre tableau imprimé:

=SOMMEPROD((Janvier!$B$3:$B$250="D-G")*(Janvier!$D$3:$D$250)) à

=SOMMEPROD((Janvier!$B$3:$B$250="D-G")*(Decembre!$D$3:$D$250))

actuelement je suis arrivé au 6 ieme tableau

=SOMMEPROD((Janvier!$B$3:$B$250="UCSA")*(Janvier!$G$3:$G$250))

j'en suis a la colonne G et j’arrête a la colonne S

merci à toi

Le 07/12/2017 à 21:15

Salut,

Tu peux essayer cela.

Attention pour que cela fonctionne, il faut que tu supprimes les fusions des cellules N1:N2 et R1:R2 et S1:S2 dans tes onglets mois.

Que tu nommes tes onglets mois exactement comme dans tes cellules de l'onglet" Recup données".

A savoir, il manque un accent dans le nom des onglets Février, Août et Décembre.

Ex : formule en Q2 de ton onglet "Recup données"

=SOMMEPROD((INDIRECT(Q$1&"!$B$3:$B$250")=$P2)*(INDIRECT(Q$1&"!L3C"&EQUIV($P$1;INDIRECT(Q$1&"!$A$2:$S$2");0)&":L250C"&EQUIV($P$1;INDIRECT(Q$1&"!$A$2:$S$2");0);FAUX)))

Après, il te faudra changer les trois cellules de référence (le mois, le nom de la colonne et le service) à chaque tableau et tu pourras étendre les formules au tableau

Ex : formule en AF2 de ton onglet "Recup données"

=SOMMEPROD((INDIRECT(AF$1&"!$B$3:$B$250")=$AE2)*(INDIRECT(AF$1&"!L3C"&EQUIV($AE$1;INDIRECT(AF$1&"!$A$2:$S$2");0)&":L250C"&EQUIV($AE$1;INDIRECT(AF$1&"!$A$2:$S$2");0);FAUX)))

A+

Le 09/12/2017 à 12:23

Salut Jers19 ,

merci pour ta solution, jamais vu une formule de la sorte j'essaye de mettre en pratique je ne garantie pas ma réussite suis un peu limite

merci

Cordialement Eric

Le 09/12/2017 à 12:52

Que dire " c'est de la BOMBE" ta formule mille merci Jers19 tu viens d’éclaircir mon week-end t'es bon l'ami

j’appelle cela de l'entraide bravo

il y a vraiment des crack dans le forum

milles merci Jers19 bon week-end

Le 09/12/2017 à 13:20