Ajout d'une ligne sur plusieurs onglet

Bonjour à tous,

Je suis un peu perdu, je souhaiterai faire 3 macros qui je pense sont simples, mais j'y parviens pas :(

Je voudrais avoir une macro qui me permettrait d'ajouter une ligne dont le numéro se choisit par une sélection avec une inputbox qui dirait "Sélectionner la ligne ou sera crée la nouvelle ligne" par exemple. J'aimerai que la ligne soit crée sur plusieurs onglets

De même, j'aimerai créer une macro qui supprimerai sur une ligne sur un ensemble d'onglets (défini dans la macro, c'est pas forcément tous les onglets du fichier). La ligne à supprimer serait indiquer par un nom situé en colonne A. Cette ligne ne serait pas forcément à la même place dans chaque onglet, car chaque onglet pourrait faire l'objet de tri indépendamment.

Enfin, j'aimerai créer un bouton qui permettrait de faire un tri sur une colonne sur un ensemble d'onglet.

Je met en PJ un fichier en espérant avoir été clair.

Merci beaucoup pour votre aide qui me sera très utile ! ! :)

Bonjour,

Un test à adapter à votre fichier :

Private Sub CommandButton1_Click()
Dim WS_T(), WS As Variant, L As Object
WS_T = Array("IR", "IS") 'A compléter
For Each WS In WS_T
    Set L = Worksheets(WS).Columns(1).Find(ActiveCell)
    If Not L Is Nothing Then Worksheets(WS).Cells(L.Row, 1).EntireRow.Delete
Next WS
Unload Me
End Sub

Private Sub CommandButton2_Click()
Dim WS_T(), WS As Variant, L%
L = ActiveCell.Row
WS_T = Array("IR", "IS") 'A compléter
For Each WS In WS_T
    Worksheets(WS).Cells(L, 1).EntireRow.Insert xlDown
Next WS
Unload Me
End Sub

Private Sub CommandButton3_Click()
Dim WS_T(), WS As Variant, C%
C = ActiveCell.Column
WS_T = Array("IR", "IS") 'A compléter
For Each WS In WS_T
    With Worksheets(WS).Sort
        .SortFields.Clear
        .SortFields.Add Key:=Worksheets(WS).Cells(1, C), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        .SetRange Worksheets(WS).UsedRange
        .Header = xlNo
        .Apply
        End With
Next WS
Unload Me
End Sub

Et le fichier qui va bien avec, où la macro USF est liée à la forme bleue de la page BILAN afin de faire apparaître l'USF en non modal et pouvoir sélectionner les lignes a supprimer/insérer ou colonne à trier en arrière plan.

Je vous laisse étudier et revenir vers moi avec le plus de détail possible si vous avez des questions car votre sujet initial restait tout de même très vague (un tri ce n'est pas très parlant, tri ascendant, descendant, sur quel colonne d'index, avec ou sans en tête, uniforme sur l'ensemble des onglets, etc etc ...), d'où, je pense, le peu de réponses.

Cdlt,