Aide tableau Excel

bonsoir à tous,

Je suis face à un petit problème, enfin je m'entraîne sur Excel (débutant) et j'essaie de me faire des exercices qui sont de plus en plus compliqués afin de m'améliorer et je bloque sur les 100 € supplémentaires par 10 km de trajet.

1% si CA > 50 000 €.

0,5% si expérience > 5 ans.

100 € supplémentaires par 10 KM de trajet.

J'ai trouvé ceci :

=SI(ET(B5>=50000;C5>=5);B5*1,5%;SI(B5>=50000;B5*1%;SI(C5>=5;B5*0,5%;0)))+SI(D5>=10;100;SI(D5>=20;200;SI(D5>=30;300;0)))

ça me trouve 668,40 € alors que je devrais avoir 768,40 € car > à 20km donc + 200 sur les 568,40 € initial.

Je ne sais pas si j'ai su bien vous expliquer ce que je souhaite faire mais merci par avance à vous pour votre aide.

SalariésCAExpérienceKM trajetSalaireCommissionA payer
David56 840,00 €2ans22km1 500,00 €668,40 €
Michael52 148,00 €5ans26km1 500,00 €
Nadine75 941,00 €1ans12km1 500,00 €
Alexandra45 693,00 €2ans4km1 500,00 €
Damien85 954,00 €5ans18km1 500,00 €
Léa75 215,00 €7ans16km1 500,00 €
Lyzhéa56 325,00 €11ans23km1 500,00 €
Stéphanie84 569,00 €5ans29km1 500,00 €
Laurent75 321,00 €7ans32km1 500,00 €
Robert7 569,00 €4ans17km1 500,00 €
Jeannine75 489,00 €6ans11km1 500,00 €


Bonjour,

Pour votre second SI vous ne pouvez pas raisonner ainsi. Ici la première condition est évaluée, est ce que mes 22km sont supérieurs à 10, oui, alors je rajoute 100, et ça s'arrête là. Les conditions suivantes ne sont vérifiées que si la précédente est fausse. Donc dans votre logique il faudrait vérifier si c'est supérieur à 30, puis 20, puis 10 (règle du worst case en 1er) soit :

=SI(D2>=30;300;SI(D2>=20;200;SI(D2>=10;100;0)))

Sous réserve que vos données soient numériques, 22km ne l'est pas car elle contient du texte "km", il faudrait retirer km de la cellule manuellement, ou par formule où substitue permet de remplacer km par rien, et CNUM de convertir le résultat en valeur numérique :

=SI(CNUM(SUBSTITUE(D2;"km";""))>=30;300;SI(CNUM(SUBSTITUE(D2;"km";""))>=20;200;SI(CNUM(SUBSTITUE(D2;"km";""))>=10;100;0)))

Et au lieu d'avoir des si imbriqué, mieux vaut calculer par tranche de 10 et avoir une formule plus "mathématique" qui s’adapterait quelque soit la valeur. Donc via une simple division. On divise le kilométrage par 10, ce qui donne 2.2. Donc on a une tranche de 2 en arrondi inférieur (ou via ENT qui renvoie la partir entière comme l'a proposé Oyobrans que salue), qu'on multiplie alors par 100. Ce qui donne au final :

=ARRONDI.INF(CNUM(SUBSTITUE(D2;"km";""))/10;0)*100
=SI(ET(B2>=50000;C2>=5);B2*1,5%;SI(B2>=50000;B2*1%;SI(C2>=5;B2*0,5%;0)))+ARRONDI.INF(CNUM(SUBSTITUE(D2;"km";""))/10;0)*100 'En formule finale

En espérant que ces explications vous aident à y voir plus clair.

Cdlt,

PS : Mes différentes données sont en ligne 2 contrairement à vous en 5 désolé ..

Bonsoir,

Proposition en PJ, avec un format de cellule personnalisé pour afficher ans et km, de façon à pouvoir utiliser directement le contenu numérique des cellules.

=SI(B2>=50000;B2*1%;0)+SI(C2>=5;B2*0,5%;0)+ENT(D2/10)*100
1classeur1.xlsx (10.35 Ko)

Bonsoir,

Aaaaah oui je comprends mieux, un grand merci à vous. 🙏

Quant à "km" il s'agit d'un format de cellule personnalisé donc il n'est pas pris en compte lors des calculs.

Encore Merci à vous 🙏

Oui je fais encore des erreurs stupides car j'ai commencé Excel très récemment et je m'entraîne de temps à autre lorsque j'ai le temps.

Passez une excellente soirée.

Rechercher des sujets similaires à "aide tableau"