Somme Si Ens dans 2 Onglet en colonne et en ligne
Bonjour à tous
Je cherche a rapatrier la somme d'un colonne d'un onglet pour le reporter automatiquement sur l'autre en prenant en considération 2 matrice (1 en colonne et 1 en ligne) en sachant que j'ai pas toujours de correspondance également en nombre de ligne entre les deux onglets.
J'ai essayé le formule suivante : =SOMME.SI.ENS('2'!$B$11:$B$13;'2'!$A$11:$A$13;$A$11;'2'!$B$3:$D$3;$B$3)
Malheureusement, elle est en erreur.
Avez vous une idée s'il vous plait ? Je vous joint un fichier test :)
En vous remerciant une nouvelle fois pour votre aide !
Bonne soirée
Christophe
Bonjour,
il n'y a qu'un chiffre donc c'est trop peu pour tester la formule.
Il faut juste reporter le montant de la ligne inscrite à gauche ?
Et c'est normal ce signe à entre le chiffre et le % ?
Pouvez-vous expliquer davantage votre problème ? Je n'ai pas bien compris de quoi il s'agit exactement.
Bonsoir à tous,
Oui j'ai mis que un montant pour l'exemple.
Pour le à ( c'est l'extraction de base qui est comme ca :)
(j'ai ajouté un peu plus d'éléments "cf fichier mis à jours")
Pour expliquer il faut recopier le montant actuellement en B11 de l'onglet 2 dans B12 de l'onglet 1.
Idem pour le montant actuellement en E12 de l'onglet 2 dans E11 de l'onglet 1
Pour cela, il faut prendre en considération la colonne A ( qui seront identique mais pas forcement dans le même ordre chaque mois ) puis prendre en considération la ligne 3 pour recopier le bon montant dans la bonne case.
Merci pour votre aide.
J'ai encore du mal à comprendre l'histoire de la ligne 3, d'autant que 3 cellules contiennent la même chose (B3 à D3), puis pareil avec les 3 suivantes.
Effectivement c'est pas simple à expliquer :)
La ligne 3 reprend le comprend le compte (identique de B3 A D3) mais qui ne correspond aux pas mêmes valeur. En effet les libellés des colonnes sont différents.
Ainsi, B10/C10/D10 sont associé au compte B3/C3/D3 puis cela revient de nouveau en E10/F10/G10 mais avec le compte E3/F3/G3
A disposition
Merci
Re bonsoir,
Je viens de refaire un fichier pour ce que ce soit un peu plus clair a expliquer.
J'ai 2 onglets :
1er : Mai2024 et le Second Avril 2024
Dans le second onglet AVRIL 2024 nous avons :
Colonne A (une liste de client)
Colonne B (le cumul du compte 411100 du mois précédent)
Colonne C (le cumul du compte 411100 du mois en cours)
Colonne D (L'encaissement du mois du compte 411100)
Colonne E/F/G la même chose mais avec un autre compte (411105)
J'ai besoin de rapatrier les montants figurant dans les colonnes B du compte 411100 et E du compte 411105 dans l'onglet MAI 2024 qui est sur la même base du tableau mais les lignes des clients ne seront pas forcement dans l'ordre.
En espérant que cela soit plus simple de compréhension et en vous remerciant une nouvelle fois.
A disposition,
Qui ne correspond pas aux mêmes valeurs, c'est à dire ?
Pourriez-vous donner un exemple où la place (colonne) serait différente de la B pour les 50000 ?
Ah non désolé les colonnes de bougerons jamais, uniquement les lignes "client" en jaune de l'onglet Mai 2024 ( comme dans l'exemple en PJ )
Donc dans la colonne B du mois de mai, il faut mettre le contenu de la colonne C du mois d'avril (et pareil avec E et F) ? Dans l'ordre des clients bien sûr.
Faut-il une formule qui sera adaptée chaque mois ou mieux vaut en faire une qui va chercher automatiquement le mois précédent ?
Il faut chercher le contenu de la colonne B du mois d'Avril pour mettre dans la colonne B du mois de Mai et Idem pour E du mois d'avril dans E du mois de Mai.
Chaque moi je sort un export, donc ce sera toujours un nouveau tableau
Ok, alors un simple INDEX/EQUIV suffit, pour B4 ;
=INDEX('AVRIL 2024'!$B$4:$B$14;EQUIV($A4;'AVRIL 2024'!$A$4:$A$14);0)E4 ;
=INDEX('AVRIL 2024'!$E$4:$E$14;EQUIV($A4;'AVRIL 2024'!$A$4:$A$14);0)
Sinon j'ai aussi fait cette formule pour B4 qui s'adapte au mois en cours et va chercher la feuille du mois précédent (ne marche pas pour janvier puisque ça va chercher dans la même année donc ne peut pas trouver décembre de l'année précédente) ;
=INDEX(INDIRECT("'"&MAJUSCULE(TEXTE(MOIS($B$1)-1&"-"&ANNEE($B$1);"mmmm aaaa"))&"'!$B$4:$B$14");EQUIV($A4;INDIRECT("'"&MAJUSCULE(TEXTE(MOIS($B$1)-1&"-"&ANNEE($B$1);"mmmm aaaa"))&"'!$A$4:$A$14");0))Cette formule nécessite de bien respecter les accents dans les mois de FÉVRIER, AOÛT et DÉCEMBRE (dans les noms de feuilles).
@Doux Rêveur, mille merci ! cette formule est parfaite !
=INDEX('AVRIL 2024'!$B$4:$B$14;EQUIV($A4;'AVRIL 2024'!$A$4:$A$14);0)Je ne peux pas utiliser l'autre car les noms des onglets ont en réalité rien à voir :)
J'ai une dernière question..
Imaginons dans l'onglet AVRIL ma colonne E/F et G se retrouve le mois suivant (donc onglet MAI ) en H/I et J car j'aurai 3 colonnes supplémentaire.
Les Colonnes B/C et D sont 411100 (0%) puis au lieu d'avoir 411105 (5%) en E/F et G je me retrouve avec 411110 (10%) , ce qui faussera mon calcule final.
Est-il possible d'avoir cette même formule mais en prenant en considération cela ?
Encore merci pour votre aide !
Donc il faut aller chercher dans l'autre feuille la colonne dont le nom correspond, même si elle n'est pas à la même place ?
Si oui, pourriez-vous fournir un fichier d'exemple ?
Oui dans l'idéal car je me rend compte que pour certain dossier, j'ai des comptes absent.
Du coup dans l'onglet 2 (AVRIL) j'ai mis :
A/B/C pour 411100 à 0%
E/F/G pour 411105 à 5,5%
H/I/J pour 411100 à 10%
et dans l'onglet 1 ( MAI ) j'ai mis :
A/B/C pour411100 à 0%
E/F/G pour 411102 à 2,2%
H/I/J pour 411105 à 5,5%
K/L/M pour 411110 à 10%
Il faut donc pouvoir renvoyer par exemple E/F/G de l'onglet AVRIL vers H/I/J de l'onglet MAI
Merci beaucoup !
Alors tu peux mettre ceci en B4 ;
=SIERREUR(INDEX(INDEX('AVRIL 2024'!$B$4:$M$14;0;EQUIV(B$2;'AVRIL 2024'!$B$2:$M$2;0));EQUIV($A4;'AVRIL 2024'!$A$4:$A$14);0);"")Et tu copies/colles vers les autres cellules de la ligne 4 pour les colonnes "Cumul mois précédent", le B$2 derrière le 1er EQUIV s'adaptera à la colonne.
J'ai mis jusqu'en M, tu peux bien sûr adapter s'il y a plus de colonnes.
Et attention aux noms de colonnes, j'ai vu qu'il y avait des espaces devant et derrière (ce qui est ok si c'est toujours pareil).
C'est top !
Tu peux m'envoyer la version Excel, ca fonctionne parfaitement sur la première colonne mais il n'affiche rien pour les autres colonnes, j'aimerai voir si j'oubli quelque chose... :)
Tu as bien copié/collé vers les cellules E4, H4 et K4 ?
Par contre je crois que ça ne marche que si la colonne où est mise la formule est la 1ère à avoir le nom qu'elle a (à cause du fonctionnement d'Equiv), donc si c'est la 2ème avec l'intitulé "411100 Ã 00,00 %", comme en C2, ça n'ira pas. Mais c'est modifiable (ce sera plus compliqué).
En fait ce n'était pas si compliqué, en voilà une qui tient compte des 2 critères (lignes 2 et 3) pour cibler la bonne colonne ;
=SIERREUR(INDEX(INDEX('AVRIL 2024'!$B$4:$M$14;0;EQUIV(1;(('AVRIL 2024'!$B$2:$M$2=B$2)*('AVRIL 2024'!$B$3:$M$3=B$3));0));EQUIV($A4;'AVRIL 2024'!$A$4:$A$14);0);"")Matricielle à mettre en B4 et à étirer sur tout le tableau.
Tu es un génie ! Mille Merci pour ton aide, c'est top !
Bonne journée :)