Index Equiv multicritère Le sujet est résolu

Y compris Power BI, Power Query et toute autre question en lien avec Excel
F
Finplein
Membre habitué
Membre habitué
Messages : 82
Inscrit le : 31 décembre 2012
Version d'Excel : 2011 Mac

Message par Finplein » 16 mai 2018, 11:50

Bonjour à tous,

Je suis bien conscient qu'il existe de multiples postes à ce sujet mais je ne parviens pas à m'en sortir dans ma situation. Quelqu'un aurait-il la bienveillance de m'aider?

Je m'explique...

Je souhaiterais pouvoir renvoyer un chiffre correspondant à une recherche sur 3 critères : date, titre de compte, département.

L'information à renvoyer doit être dans les cellules vertes de l'onglet "vue"' et doivent être pompées dans l'onglet "CHARGES".

Les critères :
- Date = Ligne 21 de l'onglet "Vue"
- Titre de compte = Colonne A de l'onglet "Vue"
- Département = cellule "B2" de l'onglet "Vue"

Quelqu'un pourrait-il me guider sur la construction de la formule?

Je vous remercie d'avance pour votre aide !
Tableau forum.xlsx
(20.97 Kio) Téléchargé 15 fois
A
Amadéus
Modérateur
Modérateur
Messages : 17'746
Appréciations reçues : 66
Inscrit le : 7 mai 2006
Version d'Excel : Office Excel 2003 FR et 2013FR

Message par Amadéus » 16 mai 2018, 14:08

Bonjour
Formule en C26, à incrémenter vers le vas et copier-coller sur les colonnes concernées
=RECHERCHEV($A26;DECALER(CHARGES!$A$3:$M$17;(CODE($B$2)-65)*LIGNES(CHARGES!$A$3:$M$17);0);NBVAL($B$21:B$21)+1;0)
Cordialement
Tableau forum.xlsx
(21.91 Kio) Téléchargé 13 fois
Amadéus vous informe que, pour cause de saturation, il ne peut plus répondre aux messages privés non sollicités.
F
Finplein
Membre habitué
Membre habitué
Messages : 82
Inscrit le : 31 décembre 2012
Version d'Excel : 2011 Mac

Message par Finplein » 16 mai 2018, 14:31

Merci Amadéus pour ta réponse...

Tu accepterais de me détailler ta formule?? Je ne la comprends pas ::~
A
Amadéus
Modérateur
Modérateur
Messages : 17'746
Appréciations reçues : 66
Inscrit le : 7 mai 2006
Version d'Excel : Office Excel 2003 FR et 2013FR

Message par Amadéus » 16 mai 2018, 16:54

Bonjour
Très volontiers.
=RECHERCHEV($A26;DECALER(CHARGES!$A$3:$M$17;(CODE($B$2)-65)*LIGNES(CHARGES!$A$3:$M$17);0);NBVAL($B$21:B$21)+1;0)
Pour A et janvier, la formule serait
=RECHERCHEV($A26;CHARGES!$A$3:$M$17;2;0)
Pour B et janvier
=RECHERCHEV($A26;CHARGES!$A$18:$M$32;3;0)
Soit un décalage du champ A3:M17 de 15 cellules vers le bas

Pour obtenir ce décalage du Champ de Recherche:
Le Code de la lettre A est 65, celui de B est 66
Donc CODE($B$2)-65=66-65=1
=LIGNES(CHARGES!$A$3:$M$17)=15
Décalage de Lignes pour passer du Champ de Recherche de A à celui de B:
=DECALER(Champ;Lignes;Colonnes)
=DECALER(CHARGES!$A$3:$M$17;(CODE($B$2)-65)*LIGNES(CHARGES!$A$3:$M$17);0)
Pour obtenir le décalage en colonnes:
Comme en ligne 21, les mois sont en alpha, et que 2 colonnes de la Feuille "Vue" correspondent à 1 colonne sur la feuille "CHARGES",
=NBVAL($B$21:B$21)+1=2 lorsque nous cherchons janvier qui est bien en colonne 2 sur la Feuille "CHARGES"
Cette formule s'incrémente seule quand on la colle en colonne E de la Feuille "Vue". Elle devient:
=NBVAL($B$21:D$21)+1=3
et c'est bien en colonne 3 de la Feuille "CHARGES" que se trouve Février
Donc, la formule DECALER utilisée,
Indique le décalage du champ de recherche autant de fois que le Code de la lettre choisie augmente
Indique le décalage de la colonne dans RECHERCHEV suivant le nombre de valeurs en ligne 22, par rapport au mois recherché.
Cordialement
Amadéus vous informe que, pour cause de saturation, il ne peut plus répondre aux messages privés non sollicités.
F
Finplein
Membre habitué
Membre habitué
Messages : 82
Inscrit le : 31 décembre 2012
Version d'Excel : 2011 Mac

Message par Finplein » 18 mai 2018, 08:06

euhhhh t'es une maxi machine en fait...

Merci
Répondre Sujet précédentSujet suivant
  • Sujets similaires
    Réponses
    Vues
    Dernier message