Comparaison entre deux feuille et copiage de donnée

Bonjour a tous ,

j'ai un fichier excel avec deux pages dans la page 1 la colonne A contient des codes uniques ces codes ont un code Regate qui se trouve dans la colonne B de la même page et une adresse dans la colonne E ,

dans la page 2 j'ai le code source dans la colonne E qui se répète , je ce que j'essaye de faire et de comparer la colonne A de la page 1 avec la colonne E de la page 2 si les codes sont identiques on prend le code regate et l'adresse du code A dans la page 1 et on les colle dans les colonne G et H dans la page 2 qui leurs code correspond au code de la page 1 .

Voila le code que j'ai essayé d'utiliser mais ça marche pas je recois pas les resultats que je veux

Sub copy_lignes()

Dim DerLig As Integer, i As Integer, DerLig_Bis As Integer

Application.ScreenUpdating = True
    DerLig = Sheets("Feuil7").Range("A" & Rows.Count).End(xlUp).Row
    For i = 2 To DerLig
        If Sheets("Feuil6").Range("A" & i) = Sheets("Feuil7").Range("E" & i) Then
            Sheets("Feuil6").Range("B" & i).copy Destination:=Sheets("Feuil7").Range("G" & i)
            Sheets("Feuil6").Range("E" & i).copy Destination:=Sheets("Feuil7").Range("H" & i)
        End If
    Next i

End Sub  

et voila le fichier : https://www.cjoint.com/c/FLhujieCOH3

Bonsoir,

Petit changement de méthode :

Sub CompléterAdRégate()
    Dim d As Object, k, n&, i&
    Set d = CreateObject("Scripting.Dictionary")
    With Worksheets("Feuil7")
        n = .Cells(.Rows.Count, 1).End(xlUp).Row
        For i = 2 To n
            k = .Cells(i, 2).Text & "|" & .Cells(i, 5)
            d(.Cells(i, 1).Value) = k
        Next i
    End With
    With Worksheets("Feuil6")
        n = .Cells(.Rows.Count, 5).End(xlUp).Row
        For i = 2 To n
            If d.exists(.Cells(i, 5).Value) Then
                k = Split(d(.Cells(i, 5).Value), "|")
                .Cells(i, 7).Resize(, 2).Value = k
            End If
        Next i
    End With
End Sub

Cordialement.

https://www.cjoint.com/c/FLiaWGTFTPu

Bonjour

je vous remercie de tout mon coeur ca marche parfaitement

cordialement