Recherche de la couleur de la cellule

Bonjour,

Voici mon projet

Sur deux fichiers excel séparés, je dispose d'une part d'une liste A de nom source. Dans cette liste, chaque cellule de chaque nom à une couleur différente. D'autre part, je dispose d'une liste B reprenant une partie des noms de A mais dont les cellules ne sont pas colorées. Les noms sont repris à la lettre.

Je cherche donc à attribuer à chaque cellule de la liste B, la couleur qui lui correspond dans A.

N'hesitez pas à demander si je n'ai pas été clair. Merci beaucoup

Elo

Bonjour,

P.

Bonjour,

Désolé, voici un exemple de ce à partir de quoi je commence

Bonsoir à tous,

Vois ceci :

Option Explicit
Sub test()
Dim rng As Range, r As Range, dico As Object
    Set dico = CreateObject("Scripting.Dictionary")
    dico.CompareMode = 1
    With Sheets("Feuil1")
        For Each r In .Range("a1", .Range("a" & Rows.Count).End(xlUp))
            dico.Item(r.Value) = r.Interior.ColorIndex
        Next
    End With
    Application.ScreenUpdating = False
    Set rng = Sheets("Feuil2").Range("a1", Sheets("Feuil2").Range("a" & Rows.Count).End(xlUp))
    rng.Interior.ColorIndex = xlNone
    If Not rng Is Nothing Then
        For Each r In rng
            If Not IsEmpty(r) Then
                If dico.exists(r.Value) Then
                    r.Interior.ColorIndex = dico.Item(r.Value)
                End If
            End If
        Next
    End If
    Set rng = Nothing
    Set dico = Nothing
    Application.ScreenUpdating = True
End Sub

klin89

Merci de ta réponse klin89,

L'exécution s'arrête à cette ligne "Set dico = CreateObject("Scripting.Dictionary")"

avec le message d'erreur "Un composant ActiveX ne peut pas créer d'objet"

(Je débute en VBA).

Bonjour,

dans l'éditeur VBA, il faut aller dans références et cocher "Microsof scripting runtime"

P.